Quasi-quoter which captures source

1-Usage.hs

-- Quoter unfortunately need to be in another file due to GHC staging restrictions
import Quoter

foo :: ParsedExpr
foo =
  [expr| Var "salads"  |]

-- foo =
ParsedExpr {parsedSource = " Var \"salads\"  ", parsedExpr = Var "salads"}

bar :: ParsedExpr
bar =
  [expr| Lam "f" (Lam "g" (Lam "x" (App (Var "g") (App (Var "f") (Var "x"))))) |]

-- bar =
ParsedExpr
  { parsedSource =
      " Lam \"f\" (Lam \"g\" (Lam \"x\" (App (Var \"g\") (App (Var \"f\") (Var \"x\"))))) "
  , parsedExpr =
      Lam "f" (Lam "g" (Lam "x" (App (Var "g") (App (Var "f") (Var "x")))))
  }

2-Quoter.hs

{-# LANGUAGE DeriveLift #-}
{-# LANGUAGE DeriveDataTypeable #-}

module Quoter where

import Language.Haskell.TH.Syntax
import Language.Haskell.TH.Quote

data Expr =
    Var String
  | Lam String Expr
  | App Expr Expr
    deriving (Read, Show, Data, Lift)

data ParsedExpr =
  ParsedExpr {
      parsedSource :: String
    , parsedExpr :: Expr
    } deriving (Show, Data, Lift)

expr :: QuasiQuoter
expr =
  qq $ \source -> do
    x <- maybe (Left "no parse") Right (readMaybe source)
    pure $
      ParsedExpr {
        parsedSource = source
      , parsedExpr = x
      }

qq :: Data a => (String -> Either String a) -> QuasiQuoter
qq f =
  QuasiQuoter {
      quoteExp = either fail liftData . f
    , quotePat = const (fail "soz no pats")
    , quoteType = const (fail "soz no types")
    , quoteDec = const (fail "soz no decs")
    }