Find all projects building a SCM repository

projects-by-scm.groovy

import org.jenkinsci.plugins.workflow.multibranch.WorkflowMultiBranchProject
import org.jenkinsci.plugins.workflow.job.WorkflowJob
import hudson.model.AbstractProject
import jenkins.*;
import jenkins.model.*;
import hudson.*;
import hudson.model.*;

String query = build.envVars['QUERY']

def workflowFilter = { it.pollingBaselines?.keys()?.any{ it.contains query } }

Map scmFilters = [ 
  'hudson.scm.NullSCM' : { false },
  'hudson.scm.SubversionSCM' : { it.locations.any{ it.remote.contains query } },
  'hudson.plugins.git.GitSCM' : { it.userRemoteConfigs.any{ it.url.contains query } }
]

def print = { println it.displayName + ' [' + it.pronoun + ']  ' + it.absoluteUrl }

Jenkins.instance.allItems
.findAll{it instanceof AbstractProject}
.findAll{ scmFilters[it.scm.class.name]?.call(it.scm)  }
.each print

Jenkins.instance.allItems
.findAll{it instanceof WorkflowMultiBranchProject}
.findAll{ it.items?.any(workflowFilter) }
.each print
  
Jenkins.instance.allItems
.findAll{it instanceof WorkflowJob}
.findAll{!(it.parent instanceof WorkflowMultiBranchProject)}
.findAll(workflowFilter)
.each print