trix_color_attributes.coffee

getHexColor = (color) ->
  return "" unless color
  return color if /^#/.test(color)
  rgbValues = getRGBValues(color)
  hexValues = rgbValues.map(numberToHex)
  "#" + hexValues.join("")

numberToHex = (number) ->
  "0#{number.toString(16)}".slice(-2).toUpperCase()

getRGBValues = (color) ->
  if match = color.match(/rgba?\((\d+),\s*(\d+),\s*(\d+)/i)
    [..., r, g, b] = match
  else
    canvas = document.createElement("canvas")
    canvas.height = canvas.width = 1
    context = canvas.getContext("2d")
    context.fillStyle = color
    context.fillRect(0, 0, 1, 1)
    {data} = context.getImageData(0, 0, 1, 1)
    [r, g, b] = data
  [r, g, b].map(Number)
  
createColorParser = ->
  (element) ->
    while element and element.tagName isnt "TRIX-EDITOR"
      if styleColor = element.style[@styleProperty]
        if color = getHexColor(styleColor)
          return color
      element = element.parentElement

Trix.config.textAttributes.foregroundColor =
  inheritable: true
  styleProperty: "color"
  parser: createColorParser()
  
Trix.config.textAttributes.backgroundColor =
  inheritable: true
  styleProperty: "backgroundColor"
  parser: createColorParser()