A demonstration of different usages of Xtend extension methods

0-kotlin-ext-methods.kt

fun main(args: Array<String>) {
    val i = 1
    i.doSomething()   // FINE
	
    val s = "string"
    s.doSomething()   // FINE
    
    val col = linkedListOf(i, s)
    col forEach { it.doSomething() }   // COMPILATION ERROR
}

fun Int.doSomething() { println("This is a List Extension")  }
fun String.doSomething() { println("This is a Set Extension")  }

1-xtend-extmeth-polymorphism.xtend

package uqbar

class Extensions {
    def static void main(String[] args) {
    	val col = newLinkedList(i, s)
    	col.forEach [ it.doSomething() ]  // <-- FINE   
    }
	
    def static dispatch doSomething(Integer i) { 
        println("This is an Integer Extension") 
    }
    def static dispatch doSomething(String i) { 
        println("This is a String Extension") 
    }
	
}

2-xtend-extmeth-different-implementations.xtend

package uqbar

class Extensions {
//	static extension ExtensionProvider = new PrintingExtensionProvider
	static extension ExtensionProvider = new NothingExtensionProvider
	
    def static void main(String[] args) {
	val i = 1
    	i.doSomething()   // FINE
	
    	val s = "string"
    	s.doSomething()   // FINE
    
    	val col = newLinkedList(i, s)
    	col.forEach [ it.doSomething() ]  // FINE   
    }
	
}

interface ExtensionProvider {
	def void doSomething(Object obj)	
}	

class PrintingExtensionProvider implements ExtensionProvider {
	override doSomething(Object obj) {
		println("This is an Extension") 
	}
}

class NothingExtensionProvider implements ExtensionProvider {
	override doSomething(Object obj) {
		// does nothing
	}
}

3-xtend-extmeth-differentProvidersAndDispatch.xtend

package uqbar

class Extensions {
//	static extension ExtensionProvider = new PrintingExtensionProvider
	static extension ExtensionProvider = new NothingExtensionProvider
	
	def static void main(String[] args) {
		val i = 1
    	i.doSomething()   // FINE
	
    	val s = "string"
    	s.doSomething()   // FINE
    
    	val col = newLinkedList(i, s)
    	col.forEach [ it.doSomething() ]  // FINE   
	}
	
}

interface ExtensionProvider {
	def void doSomething(Object obj)	
}	

class PrintingExtensionProvider implements ExtensionProvider {
	def dispatch doSomething(String obj) {            << multiple dispatch here
		println("This is an String Extension") 
	}
	def dispatch doSomething(Integer obj) {           << multiple dispatch here
		println("This is an Integer Extension") 
	}
}

class NothingExtensionProvider implements ExtensionProvider {
	override doSomething(Object obj) {
		// does nothing
	}
}