0.coffee

fs = require 'fs'

describe '#readFile', ->
  content = null
  done = false

  beforeEach ->
    runs ->
      fs.readFile __filename, (error, data) ->
        throw error if error?
        content = data
        done = true

    waitsFor ->
      done

  it 'reads the contents of the file', ->
    runs ->
      expect(content).not.toBeNull()

1.coffee

fs = require 'fs'

describe '#readFile', ->
  content = null

  beforeEach (done) ->
    fs.readFile __filename, (error, data) ->
      throw error if error?
      content = data
      done()

  it 'reads the contents of the file', ->
    expect(content).not.toBeNull()

2.coffee

express = require 'express'
request = require 'request'
{ expect } = require 'chai'

app = express.createServer()
app.get '/register', (_, response) ->
  response.send 200
server = app.listen 8500

describe '/register', ->
  beforeEach (done) ->
    request 'http://localhost:8500/register',
      (error, response) =>
        return error if error?
        @response = response
        done()

  it 'is successful', ->
    expect(@response.statusCode).to.equal 200

3.coffee

express = require 'express'
socketIo = require 'socket.io'
ioClient = require 'socket.io-client'
vows = require 'vows'
assert = require 'assert'

app = express.createServer()
app.get '/', (_, response) ->
  response.send 200
server = app.listen 8500

io = socketIo.listen server
io.sockets.on 'connection', (socket) ->
  socket.emit 'message', 'hi'

vows
  .describe('Socket server')
  .addBatch
    'when a client connects':
      topic: ->
        socket = ioClient.connect 'http://localhost:8500'
        socket.on 'message', @callback
        return undefined

      'sends a welcome message to them':  (message, _) ->
        assert.equal message, 'hi'
  .export(module)

4.coffee

request = require 'request'
events = require 'events'
vows = require 'vows'
assert = require 'assert'
nock = require 'nock'

class Google
  @search: (query, callback) ->
    options =
      uri: 'http://www.google.com/search'
      qs:
        q: query
    request options, callback

vows
  .describe('Google')
  .addBatch
    '.search':
      topic: ->
        query = 'q'
        nock('http://www.google.com')
          .get("/search?q=#{query}")
          .reply 200
        promise = new events.EventEmitter
        Google.search query, (_, response) =>
          promise.emit 'success', response
        promise

      'searches google for the given query': (_, response) ->
        assert.equal response.statusCode, 200
  .export module