In a couple of minutes I've got a first version of validating pull syntax via clojure.spec?!

datomic_pull_spec.clj

(s/def ::attr-name
  qualified-keyword?)

(s/def ::recursion-limit
  (s/or :num pos-int?
        :str #{"..."}))

(s/def ::wildcard
  (s/or :str #{"*"}
        :sym #{'*}))

(s/def ::limit
  (s/or :str #{"limit"}
        :sym #{'limit}))

(s/def ::limit-expr
  (s/cat :limit ::limit
         :attr-name ::attr-name
         :amount (s/or :num pos-int?
                       :nil nil?)))

(s/def ::default-expr
  (s/cat :default (s/or :str #{"default"}
                        :sym #{'default})
         :attr-name ::attr-name
         :value any?))

(s/def ::attr-expr
  (s/or :limit ::limit-expr
        :default-expr ::default-expr))

(s/def ::map-spec
  (s/map-of (s/or :attr-name ::attr-name
                  :limit-expr ::limit-expr)
            (s/or :query ::query
                  :recursion-limit ::recursion-limit)))

(s/def ::attr-spec
  (s/or :attr-name ::attr-name
        :wildcard ::wildcard
        :map-spec ::map-spec
        :attr-expr ::attr-expr))

(s/def ::query
  (s/+ ::attr-spec))

It's not production ready, but this took me just a few minutes to throw together. Wow.

user> (clojure.spec/conform ::query '[{:dash/items [:item/name :item/size]}])
[:query [[:map-spec #:dash{:items [:query [[:attr-name :item/name] [:attr-name :item/size]]]}]]]
user> (clojure.spec/conform ::query '[:item/name :item/size])
[:query [[:attr-name :item/name] [:attr-name :item/size]]]
user>