Alphys' Puzzle (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Alphys' Puzzle
author JC
homepage www.puzzlescript.net
again_interval 0.1

========
OBJECTS
========

Background
Black

MoveDown
transparent

MoveUp
transparent

MoveLeft
transparent

MoveRight
transparent

NoFlavor
transparent

OrangeFlavor
transparent

LemonFlavor
transparent

TempYellow
transparent

Goal
White
.000.
00000
.000.
00000
.000.

Player
#333333 #381510 #F6CB47 #75A3DB
.111.
12221
33233
.333.
.000.

PinkTile
Pink

GreenTile
Green

RedTile
Red

YellowTile
Yellow

OrangeTile
Orange

PurpleTile
Purple

BlueTile
Blue


=======
LEGEND
=======


Flavor = LemonFlavor or OrangeFlavor or NoFlavor


. = Background
@ = Player
P = PinkTile
G = GreenTile
R = RedTile
Y = YellowTile
O = OrangeTile
L = PurpleTile
B = BlueTile
F = NoFlavor
S = Goal

=======
SOUNDS
=======

================
COLLISIONLAYERS
================

MoveLeft, MoveRight, MoveUp, MoveDown
Background
OrangeFlavor,LemonFlavor,NoFlavor
TempYellow
PinkTile, GreenTile, YellowTile, OrangeTile, PurpleTile, BlueTile, Goal
Player, Redtile

======
RULES
======

[Player MoveDown] -> [DOWN Player]
[Player MoveUp] -> [UP Player]
[Player MoveLeft] -> [LEFT Player]
[Player MoveRight] -> [RIGHT Player]

[Player OrangeTile] [Flavor] -> [Player OrangeTile] [OrangeFlavor]
[Player PurpleTile] [Flavor] -> [Player PurpleTile] [LemonFlavor]

UP [UP Player | PurpleTile] -> [| Player PurpleTile MoveUp] again
DOWN [DOWN Player | PurpleTile] -> [| Player PurpleTile MoveDown] again
LEFT [LEFT Player | PurpleTile] -> [| Player PurpleTile MoveLeft] again
RIGHT [RIGHT Player | PurpleTile] -> [| Player PurpleTile MoveRight] again

[YellowTile] -> [YellowTile TempYellow]

[BlueTile][OrangeFlavor] -> [BlueTile TempYellow][OrangeFlavor]

[BlueTile | YellowTile] -> [BlueTile TempYellow | YellowTile]

UP [UP Player | TempYellow] -> [|Player MoveDown TempYellow] again
DOWN [DOWN Player | TempYellow] -> [|Player MoveUp TempYellow] again
LEFT [LEFT Player | TempYellow] -> [|Player MoveRight TempYellow] again
RIGHT [RIGHT Player | TempYellow] -> [|Player MoveLeft TempYellow] again

[TempYellow] -> []

==============
WINCONDITIONS
==============
All Player On Goal

=======
LEVELS
=======

message Red tiles are impassable! You can not walk on them!

message Yellow tiles are electric! They will electrocute you!

message Orange tiles are orange-scented. They will make you smell delicious!

message Blue tiles are water tiles, swim through if you like but...

message If you smell like oranges the pirahnas will bite you!

message If a blue tile is next to a yellow, the water will also zap you!

message Purple tiles are slippery! You will slide to the next tile!

message However, the slippery soap smells like lemons, which pirahnas do not like!

FBGYPGLPYGRYPRGPOYRRORYPYYGGBYBOGGGRGGGR.
.GOLBORRBYRRBBBRRRPPRBPGRLOBOLLPBRGRGRGR.
@PRPPBBRORPBLRPYGLOLYLLRRPOBLLBYPRGRGRGRS
.GYBYRPGOLLOPROPORBBPOBGOPBLOYBPPGGGGRGG.

message Thank you for playing!