Mad Bomber (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Bomber
author jc
homepage www.puzzlescript.net

========
OBJECTS
========

Background
LightGrey

Signal
transparent

MoreBoom
transparent

CloseMe
transparent

Goal
Orange Black
.000.
01110
01110
01110
01110


Boom8
Orange Yellow White
.1..1
10111
10001
10101
.1.1.

Boom7
Orange Yellow White
.1..1
10111
10001
10101
.1.1.

Boom6
Orange Yellow White
.1..1
10111
10001
10101
.1.1.

Boom5
Orange Yellow White
.1..1
10111
10001
10101
.1.1.

Boom4
Orange Yellow White
.1..1
10111
10001
10101
.1.1.

Boom3
Orange Yellow White
.1..1
10111
10001
10101
.1.1.

Boom2
Orange Yellow White
.1..1
10111
10001
10101
.1.1.

Boom1
Orange Yellow White
.1..1
10111
10001
10101
.1.1.

Wall
Grey Darkgrey
00010
11111
01000
11111
00010

LeadWall
Darkgrey Black
00000
01110
00000
01110
00000

Player
Black Orange White
.111.
00000
22222
.000.
.2.2.

Dead
Black Orange White
.....
.....
.02..
10202
10202
PlungerUp
Black Red White
.000.
..0..
11111
12221
11111

PlungerDown
Black Red White
.....
.000.
11111
12221
11111

M80
Darkgrey Red
.....
...0.
..0..
1111.
1111.

TNT
Darkgrey Red
..0..
.111.
.111.
.111.
.111.

C4
Darkgrey Darkgreen Red
11011
22022
21022
22012
11011

Nbomb
Darkgrey yellow
01110
11011
10001
11011
01110

DoorCL
Brown
0....
0....
0....
0....
0....

DoorCR
Brown
....0
....0
....0
....0
....0

DoorCU
Brown
00000
.....
.....
.....
.....

DoorCD
Brown
.....
.....
.....
.....
00000


DoorOL
Brown
0....
0....
0....
0....
0....

DoorOR
Brown
....0
....0
....0
....0
....0

DoorOU
Brown
00000
.....
.....
.....
.....

DoorOD
Brown
.....
.....
.....
.....
00000

=======
LEGEND
=======

Plungers = PlungerUp or PlungerDown

Explosives = M80 or TNT or C4 or Nbomb

Booms = Boom8 or Boom7 or Boom6 or Boom5 or Boom4 or Boom3 or Boom2 or Boom1

Doors = DoorCL or DoorCR or DoorCU or DoorCD

OpenDoors = DoorOL or DoorOR or DoorOU or DoorOD

BlockSignal = Wall or Doors or LeadWall

BlocksDoor = Wall or LeadWall

BlocksBooms = LeadWall

Destructable = Wall or Plungers or Doors or OpenDoors

Movables = Explosives or Player

. = Background
# = Wall
@ = LeadWall
P = Player
B = PlungerUp
M = M80
T = TNT
C = C4
N = Nbomb
A = DoorCL
D = DoorCR
W = DoorCU
S = DoorCD
G = Goal

=======
SOUNDS
=======

Sfx0 71711104
Sfx1 69685504
Sfx2 63243302

================
COLLISIONLAYERS
================

Background
Signal, MoreBoom
CloseMe
Plungers, Goal
Player, Wall, Explosives, Dead, LeadWall
Doors, OpenDoors
Booms

======
RULES
======

[Booms Player] -> [Booms Dead]
[Booms Destructable] -> [Booms]
[Booms Explosives] -> [Booms Explosives Signal] again
[Booms] -> [] Sfx2

[> Player | Explosives] -> [> Player | > Explosives]

(----DOORS----)

(prevent moving through closed doors)
LEFT [LEFT Movables | DoorCR] -> cancel
RIGHT [RIGHT Movables | DoorCL] -> cancel
DOWN [DOWN Movables | DoorCU] -> cancel
UP [UP Movables | DoorCD] -> cancel

(prevent moving through open doors)
[LEFT Movables DoorOL] -> cancel
[RIGHT Movables DoorOR] -> cancel
[DOWN Movables DoorOD] -> cancel
[UP Movables DoorOU] -> cancel

(Open closed doors when moving through them)
LEFT [LEFT Movables DoorCL | no BlocksDoor] -> [LEFT Movables | DoorOD] Sfx0
RIGHT [RIGHT Movables DoorCR | no BlocksDoor] -> [RIGHT Movables | DoorOU] Sfx0
DOWN [DOWN Movables DoorCD | no BlocksDoor] -> [DOWN Movables | DoorOR] Sfx0
UP [UP Movables DoorCU | no BlocksDoor] -> [UP Movables | DoorOL] Sfx0

(Push open doors shut)
LEFT [LEFT Movables | DoorOR] -> [LEFT Movables | DoorOR CloseMe]
RIGHT [RIGHT Movables | DoorOL] -> [RIGHT Movables | DoorOL CloseMe]
DOWN [DOWN Movables | DoorOU] -> [DOWN Movables | DoorOU CloseMe]
UP [UP Movables | DoorOD] -> [UP Movables | DoorOD CloseMe]

LEFT [ | DoorOD CloseMe] -> [ DoorCL | ] Sfx1
RIGHT [ | DoorOU CloseMe] -> [ DoorCR | ] Sfx1
DOWN [ | DoorOR CloseMe] -> [ DoorCD | ] Sfx1
UP [ | DoorOL CloseMe] -> [ DoorCU | ] Sfx1

(----BLOWING UP BOMBS----)

LATE [Player PlungerUp | no BlockSignal]-> [Player PlungerDown | Signal]
LATE [Signal|no BlockSignal] -> [Signal|Signal]

LATE [C4 Signal] -> [Boom4] again
LATE [TNT Signal] -> [Boom3] again
LATE [M80 Signal] -> [Boom2] again
LATE [Nbomb Signal] -> [Boom8] again

LATE [Booms BlocksBooms] -> [BlocksBooms]
LATE [Boom8 | no Booms] -> [Boom8 | Boom7]
LATE [Booms BlocksBooms] -> [BlocksBooms]
LATE [Boom7 | no Booms] -> [Boom7 | Boom6]
LATE [Booms BlocksBooms] -> [BlocksBooms]
LATE [Boom6 | no Booms] -> [Boom6 | Boom5]
LATE [Booms BlocksBooms] -> [BlocksBooms]
LATE [Boom5 | no Booms] -> [Boom5 | Boom4]
LATE [Booms BlocksBooms] -> [BlocksBooms]
LATE [Boom4 | no Booms] -> [Boom4 | Boom3]
LATE [Booms BlocksBooms] -> [BlocksBooms]
LATE [Boom3 | no Booms] -> [Boom3 | Boom2]
LATE [Booms BlocksBooms] -> [BlocksBooms]
LATE [Boom2 | no Booms] -> [Boom2 | Boom1]
LATE [Booms BlocksBooms] -> [BlocksBooms]

LATE [Signal] -> []

==============
WINCONDITIONS
==============

All Player on Goal
No Dead

=======
LEVELS
=======

#################
#.B#####B...#####
#P.#####..M.#####
##S######W#######
#............##G#
#.##.####.M.#####
#....####...#####
#################

###G#########
#############
#############
#############
#############
#.....#.....#
#.....#.M.C.#
#P....A.....#
#.....@.....#
#.....@.....#
###S@@@@@W###
#.....@.....#
#.....@.....#
#..B..D..B..#
#.....#.....#
#.....#.....#
#############

Message You Win!