Visit the github page of a Vundle managed plugin

VundleWeb

function! VundleVisitPluginPage(plugin_name)
    if !exists('g:vundle#bundles')
        echomsg 'Could not find Vundle plugins'
        return
    endif
    if !exists('g:web_browser')
        echomsg 'Set your web browser executable to g:web_browser'
        return
    endif
    let uri = ''
    for bundle in g:vundle#bundles
        if bundle.name == a:plugin_name
            let uri = bundle.uri
            break
        endif
    endfor
    if empty(uri)
        echomsg 'Could not find Plugin' plugin_name
        return
    endif
    if uri !~ 'github.com'
        echomsg 'Plugin'  plugin_name 'has a non-github URI:' bundle.uri
        return
    endif
    silent exec '!' . g:web_browser . ' ' . uri
    redraw!
endfunction

function! VundleWebComplete(a,c,d)
    if exists('g:vundle#bundles')
        return join(map(copy(g:vundle#bundles), 'v:val.name'), "\n")
    endif
endfunction

command! -nargs=1 -complete=custom,VundleWebComplete VundleWeb
    \ call VundleVisitPluginPage(<f-args>)