PKGBUILD for Guake 0.7.2 with the keybinder patch

guake.install

pkgname=guake

post_install() {
  usr/sbin/gconfpkg --install ${pkgname}
  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
}

pre_upgrade() {
  pre_remove $1
}

post_upgrade() {
  post_install $1
}

pre_remove() {
  usr/sbin/gconfpkg --uninstall ${pkgname}
}

post_remove() {
  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
}

PKGBUILD

# $Id$
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Angel Velasquez <[email protected]>
# Contributor: Wilson Pinto Júnior (N3RD3X) <[email protected]>
# Contributor: Attila Bukor <[email protected]>

pkgname=guake
pkgver=0.7.2.1
pkgrel=1
pkgdesc='Drop-down terminal for GNOME'
arch=('i686' 'x86_64')
url="https://github.com/Guake/guake/"
license=('GPL')
depends=('python2-notify' 'vte' 'python2-gconf' 'python2-dbus' 'python2-xdg' 'libutempter' 'python2-keybinder2')
makedepends=('intltool' 'gnome-common')
install=$pkgname.install
source=(guake-0.7.2-keybinder.tar.gz::https://github.com/jenrik/guake/archive/0.7.2-keybinder.tar.gz)
md5sums=('a0816c163afba4ee03f01c6b8e5c4552')

prepare() {
  cd "$srcdir/guake-0.7.2-keybinder"

  # Python2 fix
  sed -i 's|/usr/bin/env python|/usr/bin/python2|' src/guake/prefs.py
}

build() {
  cd "$srcdir/guake-0.7.2-keybinder"
  ./autogen.sh --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
               --disable-static --disable-schemas-install \
               --with-gconf-schema-file-dir=/usr/share/gconf/schemas \
               PYTHON=python2
  make
}

package() {
  cd "$srcdir/guake-0.7.2-keybinder"
  make DESTDIR="$pkgdir" install
}