econTest2.ec

import "ecere"

class Unit
{
   String name;
   public property const String name
   {
      set { delete name; name = CopyString(value); }
      get { return name; }
   }
   ~Unit() { delete name; }
}
class Peasant : Unit { }
class King : Unit { }
class Knight : Unit { }
class Dragon : Unit { }
class Game
{
   public Array<Unit> units;
   ~Game()
   {
      if(units) units.Free();
      delete units;
   }
}

class App : Application
{
   void Main()
   {
      Game game
      { { [
         King { name = "Arthur" },
         Peasant { name = "Pyp" },
         Peasant { name = "Eleanor" },
         Dragon { name = "Smaug" }
      ] } };
      ECONParser parser { };
      File f = FileOpen("units.econ", write);
      if(f)
      {
         WriteECONObject(f, game._class, game, 0);
         delete f;
      }
      delete game;

      f = FileOpen("units.econ", read);
      if(f)
      {
         parser.f = f;
         parser.GetObject(class(Game), &game);
         PrintLn(game);
         delete f;
      }
      delete game;
      delete parser;
   }
}