heapAndStackAndClassAndStruct.ec

struct MyStruct { int x, y; };
class OtherClass { };

class MyClass
{
   MyStruct myStructMember { };
   OtherClass myClassMember { };
   int a, b;
};

/*
the globalClassInstance handle is allocated in the globals storage
the globalClassInstance object is allocated on the heap
its myStructMember is allocated as part of that same heap block, just like the 'a' and 'b' member, and the handle for myClassMember
the myClassMember object itself is allocated as its own block from the heap

Global class instances are automatically deleted when unloading the module
*/
MyClass globalClassInstance { };

/*
globalStructInstance itself is allocated in the globals storage
*/
MyStruct globalStructInstance { };

void someFunction()
{
   int c, d;
   /*
   localStructInstance itself is allocated on the stack
   */
   MyStruct localStructInstance { };

   /*
   the localClassInstance handle is allocated on the stack
   the localClassInstance object is allocated on the heap
   its myStructMember is allocated as part of that same heap block, just like the 'a' and 'b' member, and the handle for myClassMember
   its myClassMember object itself is allocated as its own block from the heap
   */
   MyClass localClassInstance { };
   
   // NOTE: Currently, function/method-local classes instances must always be explicitly freed
   //       (Sometimes the API will automatically take care of this, e.g. Window, GeoPoint)
   //       This is not the case for 'struct' (they are on the stack, and the stack is automatiaclly popped when exiting the function)
   delete localClassInstance;
}