jenkins dsl cleanup job slaves docker

jenkins_docker_cleanup.gdsl

// got it from https://gist.github.com/tomnomnom/53998ec618a17d61153911f9b5ade0ed
// The ArrayList of slaves is not serializable, so fetching them should be marked as @NonCPS so that
// no attempt is made to serialize and save the local state of the function. See here for details:
// https://github.com/jenkinsci/pipeline-plugin/blob/master/TUTORIAL.md#serializing-local-variables

@NonCPS
def getSlaves() {
    def slaves = []
    jenkins.model.Jenkins.instance.slaves.each {
        if (it.name.startsWith('jenkinsslave-')) {
        slaves << it.name
        }
    }
    print(slaves)
    return slaves
}

// Run a command on each slave in parallel
def jobs = [:]
getSlaves().each {

    // Use a local variable to avoid closing over a reference to 'it',
    // the value of which changes on each iteration
    def slave = it

    // Create a closure for each slave and put it in the map of jobs
    jobs[slave] = {
        node(slave) {
            // clean up docker containers and docker images
            sh 'docker rm -f $(docker ps -a -q)'
            sh 'docker rmi -f $(docker images -a -q)'
        }
    }
}

// Run the closures in parallel
parallel jobs

//triggers {
//    cron('@midnight')
//}