Stackoverflow API to CSV Scripts

load-so.cypher

create constraint on (q:Question) assert q.id is unique;
create constraint on (u:User) assert u.id is unique;
create constraint on (t:Tag) assert t.name is unique;
create constraint on (a:Answer) assert a.id is unique;
create index on :Question(title);
create index on :User(display_name);

WITH "https://api.stackexchange.com/2.2/questions?pagesize=100&order=desc&sort=creation&tagged=neo4j&site=stackoverflow&filter=!5-i6Zw8Y)4W7vpy91PMYsKM-k9yzEsSC1_Uxlf" AS url
CALL apoc.load.json(url) YIELD value
UNWIND value.items AS q
MERGE (question:Question {id:q.question_id})
ON CREATE SET question.title = q.title,
              question.share_link = q.share_link,
              question.favorite_count = q.favorite_count

FOREACH (tagName IN q.tags | MERGE (tag:Tag {name:tagName}) MERGE (question)-[:TAGGED]->(tag))
FOREACH (a IN q.answers |
   MERGE (question)<-[:ANSWERS]-(answer:Answer {id:a.answer_id})
   MERGE (answerer:User {id:a.owner.user_id}) ON CREATE SET answerer.display_name = a.owner.display_name
   MERGE (answer)<-[:PROVIDED]-(answerer)
)

WITH * WHERE NOT q.owner.user_id IS NULL
MERGE (owner:User {id:q.owner.user_id}) ON CREATE SET owner.display_name = q.owner.display_name
MERGE (owner)-[:ASKED]->(question);

questions.csv

so-to-csv.sh

# https://api.stackexchange.com/2.2/questions?pagesize=100&order=desc&sort=creation&tagged=neo4j&site=stackoverflow&filter=!5-i6Zw8Y)4W7vpy91PMYsKM-k9yzEsSC1_Uxlf

curl -L -o - 'https://dev.neo4j.com/so-api' | gzip -d > so.json

jq -r '["user_id", "title", "created", "id", "view_count" ], \
(.items[] | [.owner.user_id, .title, .creation_date, .question_id, .view_count]) | \
@csv' so.json > questions.csv

jq -r '["user_id", "display_name", "reputation"], \
(.items[] | .owner | [.user_id, .display_name, .reputation]) | \
@csv' so.json > users.csv

users.csv