jenkins universal credential closure

0.groovy scripts for jenkins credentials.md

🛠 groovy scripts for jenkins credentials

... keeping update ...

jenkins-universal-credential-closure.groovy

import com.datapipe.jenkins.vault.credentials.common.VaultSSHUserPrivateKeyImpl
import com.datapipe.jenkins.vault.credentials.common.VaultUsernamePasswordCredentialImpl
import com.cloudbees.plugins.credentials.impl.UsernamePasswordCredentialsImpl
import com.cloudbees.jenkins.plugins.sshcredentials.impl.BasicSSHUserPrivateKey
import com.cloudbees.plugins.credentials.CredentialsProvider
import com.cloudbees.plugins.credentials.common.StandardCredentials

def withCredential( String credentialsId, Closure body ) {
  Closure foo = { cid ->
    [
      ( VaultSSHUserPrivateKeyImpl )          : { body([ username: cid.username, sshkey: cid.privateKeyKey ]) },
      ( BasicSSHUserPrivateKey )              : { body([ username: cid.username, sshkey: cid.privateKeys.join('\n') ]) },
      ( VaultUsernamePasswordCredentialImpl ) : { body([ username: cid.username, password: cid.passwordKey ]) },
      ( UsernamePasswordCredentialsImpl )     : { body([ username: cid.username, password: cid.passwordKey ]) }
    ].find { it.key.isAssignableFrom( cid.getClass() ) }.value.call()
  }

  foo CredentialsProvider.lookupCredentials( StandardCredentials.class, jenkins.model.Jenkins.instance).find { credentialsId == it.id }
}

withCredential( 'BASIC_CREDENTIAL' ) { account ->
  println "${account.password} -> ${account.username}"
}

withCredential( 'SSH_CREDENTIAL' ) { account ->
  println "${account.sshkey} -> ${account.username}"
}