Wrapper Applescript for toggling Mark Jaquith's Localdev script: https://github.com/markjaquith/Localdev on and off. Can be used with FastScripts: http://www.red-sweater.com/fastscripts/ and set to a global keyboard shortcut. (I used Cmd+Shift+L). Also provides a growl notification of the updated status.

ToggleLocalDev.scpt

# Toggle Localdev On/Off

# Fetch the status of localdev
set localdevStatus to do shell script "/usr/local/bin/localdev status | awk '{print $3}'"

if localdevStatus is equal to "on" then
  toggleLocaldev("off")
else
  toggleLocaldev("on")
end if

on toggleLocaldev(value)
	do shell script ("/usr/local/bin/localdev " & value)
	
	tell application "System Events"
		set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
	end tell
	
	if isRunning then
		tell application id "com.Growl.GrowlHelperApp"
			-- Make a list of all the notification types 
			-- that this script will ever send:
			set the allNotificationsList to ¬
				{"Localdev Status"}
			
			-- Make a list of the notifications 
			-- that will be enabled by default.      
			-- Those not enabled by default can be enabled later 
			-- in the 'Applications' tab of the growl prefpane.
			set the enabledNotificationsList to ¬
				{"Localdev Status"}
			
			-- Register our script with growl.
			-- You can optionally (as here) set a default icon 
			-- for this script's notifications.
			register as application ¬
				"Localdev" all notifications allNotificationsList ¬
				default notifications enabledNotificationsList ¬
				icon of application "Script Editor"
			
			--       Send a Notification...
			notify with name ¬
				"Localdev Status" title ¬
				"Localdev" description ¬
				"Localdev is " & value application name "Localdev"
		end tell
	end if
end toggleLocaldev