Prim

ps:prim

title Prim's Labyrith
author Jere Majava
text_color darkgreen
run_rules_on_level_start
zoomscreen 11x11
again_interval 0.05

( Procedurally generated maze using Randomized Prim's algorithm http://en.wikipedia.org/wiki/Maze_generation_algorithm#Randomized_Prim.27s_algorithm )

========
OBJECTS
========

Death
black darkred
01110
10101
11011
10101
01110

Background 
darkblue

START
transparent

Footprints
(#161e27)
#19212a
.....
.....
.....
...0.
.0...

Footprints2
#19212a
.....
..0..
0....
.....
.....


marker
transparent

maze
transparent
.....
.....
..0..
.....
.....

PrimRS
Black grey white lightgrey darkgrey
..00.
.0012
.0020
..143
.121.

PrimLS
Black grey white lightgrey darkgrey
..00.
.2100
.0200
.341.
..121

PrimR
Black grey white
..00.
.0020
.0220
..11.
.121.

PrimL
Black grey white
..00.
.0200
.0220
..11.
..121

PrimDSlm
Black grey white green darkgreen
..00.
.0200
.0224
..113
.211.

PrimUSlm
Black grey white green
..00.
.0000
.0000
.310.
..11.


PrimRSlm
Black grey white green darkgreen
..00.
.0020
.0224
..113
.121.

PrimLSlm
Black grey white green darkgreen
..00.
.0200
.4220
.311.
..121


Target
black grey darkgrey darkgreen
.1.1.
.111.
.1.1.
01110
02020

(black darkgreen darkblue #161e27
00000
10000
12000
12100
12120)

Room
darkgreen

Door
darkbrown black
00000
01110
00000
00000
00000

Locked
darkbrown black darkgreen
00000
01210
00000
00000
00000


Open
darkbrown
0....
0....
0....
.....
.....
Clear
transparent
ClearT
transparent


Hidden
black

Wall
black
(black darkblue #161e27
00020
20100
00002
10010
02001)

EdgeT
darkgrey grey
.....
.....
.....
.....
00000

EdgeL
darkgrey
....0
....0
....0
....0
....0
EdgeR
darkgrey
0....
0....
0....
0....
0....
BitL
darkgrey
.....
.....
.....
.....
....0
BitR
darkgrey
.....
.....
.....
.....
0....

Facade
darkgreen #2c4044
00010
11111
01000
.....
.....

ShadowL shl
black
0....
.0...
0....
.0...
0....
ShadowR shr
black
....0
...0.
....0
...0.
....0
ShadowU shu
black
0.0.0
.0.0.
.....
.....
.....
ShadowD shd 
black
.....
.....
.....
.0.0.
0.0.0

skull
lightgrey grey darkgrey black
.....
.....
.10..
.03..
..1.2

bones
lightgrey grey darkgrey black
.....
.....
1....
.0.0.
232.1

slime
green darkgreen #161e27
.....
.....
.....
..10.
1.211

slimeR
green darkgreen
.....
.....
1.10.
.....
.....
slimeL
green darkgreen
.....
.....
.01.1
.....
.....
slimeD
green darkgreen
..1..
.....
..1..
..0..
.....
slimeU
green darkgreen
.....
..0..
..1..
.....
..1..
Stain
green darkgreen
.....
.....
..01.
..1..
.....

wood
darkbrown black
.....
.....
..0.
01.10
.01..

(blood
#471c21
.....
0....
...00
.000.
..0.0)

Grate
#161e27 black darkgreen
.....
00000
01010
01010
00000

Crack
#161e27
.....
.....
....0
..00.
0.0..

Catnip
purple #161e27
.0...
.1.0.
01.1.
10.10
.1..1

PawsS c
brown darkbrown orange darkred
.....
..0.0
..101
.0000
.020.

PawsR
brown purple orange darkred
.....
..0.0
2.101
00030
.000.

PawsL
brown purple orange darkred
.....
0.0..
101.2
03000
.000.

Key
orange brown
.....
.....
.....
.01..
.....

SkeletonR
lightgrey grey darkgrey black #19212a white
...05
...53
..020
.021.
..142

SkeletonL
lightgrey grey darkgrey black #19212a white
.50..
.35..
.021.
..120
.241.

SkeletonRSlm
lightgrey grey darkgrey black #19212a white green darkgreen
...06
...67
..020
.021.
..142

SkeletonLSlm
lightgrey grey darkgrey black #19212a white green darkgreen
.60..
.76..
.020.
..120
.241.



HasKey
transparent

Zero 0
darkblue
.00..
0..0.
0..0.
0..0.
.00..

One 1
darkblue
..0..
.00..
..0..
..0..
..0..

Two 2
darkblue
.00..
0..0.
..0..
.0...
0000.

Three 3
darkblue
000..
...0.
..0..
...0.
000..

Four 4
darkblue
...0.
..00.
.0.0.
0000.
...0.

Five 5
darkblue
0000.
0....
000..
...0.
000..

Six 6
darkblue
.00..
0....
000..
0..0.
.00..

Seven 7
darkblue
0000.
...0.
..0..
..0..
..0..

Eight 8
darkblue
.00..
0..0.
.00..
0..0.
.00..

Nine 9
darkblue
.00..
0..0.
.000.
...0.
.00..

Ones
transparent

Tens
transparent

plusone p
transparent


=======
LEGEND
=======

# = Wall


primS = PrimLS or PrimRS
PrimSlm = PrimLSlm or PrimRSlm or PrimDSlm or PrimUSlm
Prim = PrimL or PrimR
PrimNoS = Prim or PrimSlm
player = prim or prims or PrimSlm

Visible = Clear or Player or ClearT
Edge = EdgeT or EdgeL or EdgeR
shadow = shl or shr or shu or shd

Rubble = Skull or Slime or Wood or Grate or Crack or bones or Catnip
SlimeF = SlimeR or SlimeL or SlimeU or SlimeD


x = start and maze and PrimR and target

DungeonElements = door or open or facade or rubble or footprints or footprints2

number = 1 or 2 or 3 or 4 or 5 or 6 or 7 or 8 or 9 or 0

Paws = PawsL or PawsR

Skeleton = SkeletonR or SkeletonL
SkeletonSlm = SkeletonRSlm or SkeletonLSlm

Remains = Skull or Bones

=======
SOUNDS
=======

target create  92709108
(player move 31166707)
player cantmove 71782707
open create 58752107
SlimeF destroy 80304707
Key destroy 59969308
Locked destroy 97702308
EndLevel 85565903
skeleton move 35994304
Death create 37384508
restart 37604508


sfx0 60740509 (Catnip)
sfx1 98662308
sfx2 64336508

sfx3 58752107 (Door)
sfx4 95213308 (Purr)

sfx5 96990708 (Skull)
sfx6 93424708 (Drop Skull)

sfx9 18230302 (bones fall!)


sfx7 37703708
sfx8 37352508

(
sfx8 11908308 (tii tada daa....)
sfx9 94473108 (low rumble)

sfx7 56741903 (buijuiju)
sfx0 2577708 (rocks rolling)
sfx0 7086908 (pretty good push sound)
sfx0 55018908 (LOUD!)
sfx0 37352508 (käkätys)
sfx0 13609108 (shlkm)
sfx0 58167908 (DESTROY PUNY HUMANS!)
sfx0 72535108 (zilurp)
sfx0 66334908 (kinda crazy)
sfx0 45016508 (metallic chime)
sfx0 25858308 (njiuviuviu)
sfx0 89716508 (Dudhudhudhudhhhh...)
sfx0 93863108 (iso fläpätys)
sfx0 5814108  (shhh KHOOO...)
sfx0 84615508 (däjäu)
sfx0 80966508 (vjom)
)
================
COLLISIONLAYERS
================

Background
start
clear, cleart
room
maze, footprints
footprints2
grate, crack
facade
target, haskey
marker
open
bones, skull, slime, wood, catnip, Key
Player, Wall, Door, Paws, PawsS, Skeleton, SkeletonSlm
Locked
SlimeF, Stain
hidden
shl
shr
shu
shd
EdgeT
EdgeR
EdgeL
BitL
BitR
ones, tens
number
plusone
Death

======
RULES
======

[ action player target no start ][ paws hidden ] -> message You can't leave Paws behind!
[ action player target no start ][ pawss hidden ] -> message You can't leave Paws behind!
[ action player target no start | paws ] -> win
[ action player target no start | | paws ] -> win

( Start a new level)
([ action player target no start | paws ][ dungeonelements ] -> [ action player target | paws ][ ]
[ action player target no start | paws ][ no wall no start no player no paws ] -> [ action player target | paws  ][ wall ]
[ action player target no start | paws ][ start ] -> [ wall | wall ][ start maze player target ] 
[ action player target no start ] -> message You can't leave Paws behind!
)

( Build the maze )
startloop
random [ maze | wall | wall | wall ][ target ] -> [ maze | wall | wall | wall ][ ]
random [ maze | wall | wall | wall ] -> [ maze no wall | | | maze no wall target ]
endloop
[ target maze ] -> [ target ]
( Make 9x9 rooms... )
(random vertical [ | | | | maze | | | | ] -> [ room | room | room | room | room | room | room | room | room ]
horizontal [ no room | no room | no room | no room | room | no room | no room | no room | no room ] -> [ room | room | room | room | room | room | room | room | room ])

( Make some 2x2 rooms? )
random down [ maze | ] -> [ room | room ]
random down [ maze | ] -> [ room | room ]
random down [ maze | ] -> [ room | room ]
random down [ maze | ] -> [ room | room ]
random down [ maze | ] -> [ room | room ]
random up [ maze | ] -> [ room | room ]
random up [ maze | ] -> [ room | room ]
random up [ maze | ] -> [ room | room ]
random up [ maze | ] -> [ room | room ]
random up [ maze | ] -> [ room | room ]
left  [ no room | room | no room ] -> [ | room | room ]
random up [ maze | ] -> [ room | room ]
random up [ maze | ] -> [ room | room ]
random up [ maze | ] -> [ room | room ]
random up [ maze | ] -> [ room | room ]
random up [ maze | ] -> [ room | room ]
random down [ maze | ] -> [ room | room ]
random down [ maze | ] -> [ room | room ]
random down [ maze | ] -> [ room | room ]
random down [ maze | ] -> [ room | room ]
random down [ maze | ] -> [ room | room ]
right [ no room | room | no room ] -> [ | room | room ]


( Make 3x3 rooms... )
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
random right [ | maze | ] -> [ room | room | room ]
down [ no room | room | no room ] -> [ room | room | room ]

( Remove walls from rooms )
[ wall room ] -> [ room ]

( Make doors for rooms )
[ room | no room no wall | no door ] -> [ room | door | ]

(Just in case, remove adjacent doors, though there shouldn't be any )
[ door | door ] -> [ | ]

( Remove some of the room doors )
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]
random [ maze ][ door ] -> [ maze ][ ]

(Add the locked door next to the target)
[ maze ][ target | no wall ] -> [ maze ][ target | door locked ]


( Add Some extra doors in the corridors ! )
random [ maze | no wall | no door no room ] -> [ maze | door | ]
random [ maze | no wall | no door no room ] -> [ maze | door | ]
random [ maze | no wall | no door no room ] -> [ maze | door | ]
random [ maze | no wall | no door no room ] -> [ maze | door | ]
random [ maze | no wall | no door no room ] -> [ maze | door | ]
random [ maze | no wall | no door no room ] -> [ maze | door | ]
random [ maze | no wall | no door no room ] -> [ maze | door | ]
random [ maze | no wall | no door no room ] -> [ maze | door | ]
random [ maze | no wall | no door no room ] -> [ maze | door | ]
random [ maze | no wall | no door no room ] -> [ maze | door | ]
random [ maze | no wall | no door no room ] -> [ maze | door | ]
random [ maze | no wall | no door no room ] -> [ maze | door | ]

( Add random things )
[ marker ] -> [ ]
[ door | ] -> [ door | marker ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random rubble ]

random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ skull ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ skull ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ slime ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ slime ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ slime ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ slime ]


(Add skeletons!)
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random skeleton ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random skeleton ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random skeleton ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random skeleton ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random skeleton ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random skeleton ]
random [ maze ][ no door no wall no player no target no marker ] -> [ maze ][ random skeleton ]



( Set Paws  ant the key )
random [ room ] -> [ pawss ]
random [ room no pawss ] -> [ key ]

( Clear the maze creation markers )
[ room ] -> [ ]
[ maze ] -> [ ]
[ marker ] -> [ ]

( Venture on)
[ left  prim ] -> [ left  priml ]
[ right prim ] -> [ right primr ]

( Get the key )
late [ Player Key ] -> [ Player HasKey ] message It's a key!

( Open and close doors )
[ > Player | Door no Locked ] -> [ Player | Open no Stain ]
[ action Player no target no slime no skull | Open no Paws no pawss no Skeleton no SkeletonSlm ] -> [ Player | Door ] sfx3

[ HasKey ][ > Player | Locked ] -> [ Haskey ][ Player | Door ]
[ > Player | Locked ] -> [ Player | Locked ] message It's locked!


( Wearing the skull )
[ left  prims ] -> [ left  primls ]
[ right prims ] -> [ right primrs ]
[ action primR skull ] -> [ PrimRS ] sfx5
[ action primL skull ] -> [ PrimLS ] sfx5
[ action primRS no rubble no target ] -> [ PrimR skull ] sfx6
[ action primLS no rubble no target ] -> [ PrimL skull ] sfx6


( Slimed skeletons wander aimlessly )
[ moving Player ][ SkeletonSlm ] -> [ moving Player ][ randomdir SkeletonSlm ]
[ moving Player ][ left SkeletonSlm ] -> [ moving Player ][ left SkeletonLSlm]
[ moving Player ][ right SkeletonSlm ] -> [ moving Player ][ right SkeletonRSlm]
[ moving Player ][ SkeletonSlm hidden ] -> [ moving Player ][ random Skeleton ]


( Carrying and throwing the slime )
[ left  primslm no primLslm ] -> [ primlslm ]
[ right primslm no primRslm ] -> [ primRslm ]
[ down  primslm no primDslm ] -> [ primDslm ]
[ up    primslm no primUslm ] -> [ primUslm ]
[ action primR slime ] -> [ PrimRSlm slime ] sfx7
[ action primL slime ] -> [ PrimLSlm slime ] sfx7

right [ action primRSlm | no Door no Wall ] -> [ PrimR SlimeR | ]
left  [ action primLSlm | no Door no Wall ] -> [ PrimL SlimeL | ]
down  [ action primDSlm | no Door no Wall ] -> [ PrimL SlimeD | ]
up    [ action primUSlm | no Door no Wall ] -> [ PrimR SlimeU | ]

[ SlimeR | no wall no door ] -> [ right SlimeR | ] again
[ SlimeL | no wall no door ] -> [ left  SlimeL | ] again
[ SlimeU | no wall no door ] -> [ up    SlimeU | ] again
[ SlimeD | no wall no door ] -> [ down  SlimeD | ] again
[ > SlimeF | Door ] -> [ | Door Stain ]
[ > SlimeF | Wall ] -> [ | Wall ]

[ > SlimeF | SkeletonL ] -> [ | SkeletonLSlm ]
[ > SlimeF | SkeletonR ] -> [ | SkeletonRSlm ]


( )
[ > player ] -> [ > player footprints ] 
[ > player grate ] -> [ > player grate ] sfx1


( Paws )
(------)

( Area around Prim for Paws to follow. Re-uses the dungeon cretor markers. )
[ > Player | Paws ] -> [ Paws | Player ] 
[ Player | no Marker no wall no door ] -> [ Player | Marker ]
[ Player | Marker | no wall no door ] -> [ Player | Marker | room ]


( Paws follows Prim... )


random [ moving Player ][ Paws no room no marker | ... | room ] -> [ moving Player ][ > Paws | ... | room ]
random [ moving Player ][[ Paws | ... | Marker ] -> [ moving Player ][ > Paws | ... | marker ]
[ moving Player ][[ Paws Marker ] -> [ moving Player ][ randomdir Paws marker ]

( ...but wont step on grates, slime...)
(
[ > paws | slime ] -> [ v paws | slime ]
[ > paws | grate ] -> [ ^ paws | grate ]
)

( ...and is a bit scared of Prim wearing the skull )
[ prims ][ paws | marker ] -> [ prims ][ randomdir paws | marker ]
[ > prims | | paws ] -> [ > prims | | > paws ]
[ prims | paws ] -> [ prims | > paws ]
[ prims ][ > paws no marker | no marker | marker ] -> [ prims ][ paws | | marker ]

( Paws takes down helpless skeleton! )
[ Paws | SkeletonSlm ] -> [ > paws | random remains ] sfx9

( Paws loves catnip )
[ > paws | catnip ] -> [ > pawss | catnip ] sfx0

( Skeleton follows Prim, unless she is wearing the skull )
random [ moving PrimNoS ][ Skeleton no room no marker no hidden | ... | room ] -> [ moving PrimNoS ][ > Skeleton | ... | room ]
random [ moving PrimNoS ][[ Skeleton no hidden | ... | Marker ] -> [ moving PrimNoS ][ > Skeleton | ... | marker ]
[ Skeleton | moving PrimNoS ] -> [ > Skeleton | moving PrimNoS ]



[ > PrimS |  Skeleton ] -> [ Skeleton | PrimS ]
[ > Player | SkeletonSlm ] -> [ SkeletonSlm | Player ]


( Clear the markers)
late [ marker ] -> [ ]
late [ room ] -> [ ]

( Paws gets lost - and is found again! )
[ > Player | PawsS ] -> [ Player | PawsR ] sfx4
[ action Player | PawsS ] -> [ Player | PawsR ] sfx4

()

[ left Paws ] -> [ left PawsL ]
[ right Paws ] -> [ right PawsR ]
[ > paws ] -> [ > paws footprints2 ] 


[ left Skeleton ] -> [ left SkeletonL ]
[ right Skeleton ] -> [ right SkeletonR ]
[ > Skeleton ] -> [ > Skeleton footprints ] 

[ > skeleton|  primNoS ] -> restart
[ > primNoS | skeleton ] -> restart



( Visibility )
(------------)

[ clear ] -> [ ]
[ cleart ] -> [ ]
[ bitL ] -> [ ]
[ bitR ] -> [ ]
[ edge ] -> [ ]
[ shadow] -> [ ]
[ ] -> [ hidden ]

late [ player | no visible no door no wall ] -> [ player | clear ]
late [ player | clear | no visible no door no wall ] -> [ player | clear | clear ]
late [ player | clear | clear | no visible no door no wall ] -> [ player | clear | clear | clear ]
late [ player | clear | clear | clear | no visible no door no wall ] -> [ player | clear | clear | clear | clearT ]

late [ clear | no visible no door no wall ] -> [ clear | cleart ]
late [ clear | clear | no visible no door no wall ] -> [ clear | clear | clear ]
late [ clear | clear | clear | no visible no door no wall ] -> [ clear | clear | clear | cleart ]

late [ no clear | clear | cleart | no visible no door no wall ] -> [  | clear | cleart | cleart ]

late [ visible | ] -> [ visible no hidden | no hidden ]
late [ hidden wall | door no hidden ] -> [ wall | door ]

( Draw edges for the walls )
late up    [ Wall | no wall no hidden ] -> [ Wall | EdgeT ]
late down  [ Wall | no wall no hidden ] -> [ Wall EdgeT | Facade ]
late left  [ Wall | no wall no hidden ] -> [ Wall EdgeR | ]
late right [ Wall | no wall no hidden ] -> [ Wall EdgeL | ]
late up    [ EdgeL | no EdgeL ] -> [ EdgeL | BitL ]
late up    [ EdgeR | no EdgeR ] -> [ EdgeR | BitR ]

( Shadows)
late right [ hidden no wall | no hidden no door ] -> [ hidden | shl ]
late left  [ hidden no wall | no hidden no door ] -> [ hidden | shr ]
late down  [ hidden no wall | no hidden no door ] -> [ hidden | shu ]
late up    [ hidden no wall | no hidden no door ] -> [ hidden | shd ]


( Extra )
(-------)

( Add the numbers, to be used with levels, exp, etc.) )
late [ | 9 p ] -> [ p | 0 ]
late [ p ]   -> [ 1 ]
late [ 0 p ] -> [ 1 ]
late [ 1 p ] -> [ 2 ]
late [ 2 p ] -> [ 3 ]
late [ 3 p ] -> [ 4 ]
late [ 4 p ] -> [ 5 ]
late [ 5 p ] -> [ 6 ]
late [ 6 p ] -> [ 7 ]
late [ 7 p ] -> [ 8 ]
late [ 8 p ] -> [ 9 ]
late [ p ] -> [ ]





==============
WINCONDITIONS
==============


=======
LEVELS
=======

message Primrose and Paws, are two you lost in that procedurally generated maze again?
message Hey, where's Paws?

########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
##########################x#############################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################
########################################################

message Welcome home Prim! Go wash your hands, the dinner is ready.