simple syntax-parse macros to rearrange evaluation

$.rkt

#lang racket

(require (for-syntax syntax/parse)
         syntax/parse)

; why would you want infix syntax, when you can
; change your syntax to suit the task at hand?

(define-syntax ($ stx)
  (syntax-parse stx
    #:datum-literals ($)
    [($ v) #'v]
    [($ v (f a ... $ b ...))
     #'(f a ... v b ...)]
    [($ v (f a ...))
     #'(f v a ...)]
    [($ v (f a ...) ... (g b ... $ c ...))
     #'(g b ... ($ v (f a ...) ...) c ...)]
    [($ v (f a ...) ... (g b ...))
     #'(g ($ v (f a ...) ...) b ...)]
    ))

(define-syntax (<$ stx)
  (syntax-parse stx
    #:datum-literals ($)
    [(<$ v) #'v]
    [(<$ (f a ... $ b ...) v)
     #'(f a ... v b ...)]
    [(<$ (f a ...) v)
     #'(f v a ...)]
    [(<$ (g b ... $ c ...) (f a ...) ... v)
     #'(g b ... (<$ (f a ...) ... v) c ...)]
    [(<$ (g b ...) (f a ...) ... v)
     #'(g (<$ (f a ...) ... v) b ...)]
    ))

($ '(1 5 9) (list-ref 1) (+ 2) (/ 2 $))

(<$ (/ 2 $) (+ 2) (list-ref 1) '(1 5 9))

; improvement: find the $ marker anywhere, so that
;  ($ 5 (if (= 5 $) #t #f))
; could work