Log::Dispatch for Perl 6

Log::Dispatch.pm6

class Log::Dispatch {
        enum Level <DEBUG INFO NOTICE WARNING ERROR CRITICAL ALERT EMERGENCY>;

        class Output {
                has Level $.level = DEBUG;
                
                method format(Level $level, DateTime $ts, @args) {
                        $ts ~ ' [' ~ $level.lc ~ '] ' ~ @args>>.gist.join(' ')
                }
                
                method output(Str $msg) { ... }
        }
        
        class Screen is Output {
                method output(Str $msg) { $msg.note }
        }
        
        has Output @.outputs is rw;

        method log(Level $level, *@things) {
                my $ts = DateTime.now;
                
                @!outputs>>.&{.output(.format($level, $ts, @things)) if $level >= .level};
        }
        
        for Level::.values -> $level {
                ::?CLASS.^add_method(
                        $level.lc,
                        method (*@things) { $.log($level, @things) }
                );
        };
}