spec-tools-transformers.clj

(defmethod json-schema/accept-spec 'clojure.spec.alpha/keys [_ spec children _]
  (let [name (comp #(clojure.string/replace % "-" "_") name)
        {:keys [req req-un opt opt-un]} (impl/parse-keys (impl/extract-form spec))
        names-un (map name (concat req-un opt-un))
        names (map impl/qualified-name (concat req opt))
        required (map impl/qualified-name req)
        required-un (map name req-un)
        all-required (not-empty (concat required required-un))]
    (#'json-schema/maybe-with-title
     (merge
      {:type "object"
       :properties (zipmap (concat names names-un) children)}
      (when all-required
        {:required (vec all-required)}))
     spec)))

;; https://github.com/metosin/spec-tools/pull/110
(defmethod json-schema/accept-spec :spec-tools.visitor/spec [_ spec children _]
  (let [[_ data] (spec-tools.impl/extract-form spec)
        json-schema-meta (reduce-kv
                           (fn [acc k v]
                             (if (= "json-schema" (namespace k))
                               (assoc acc (keyword (name k)) v)
                               acc))
                           {}
                           (into {} data))
        extra-info (-> data
                       (select-keys [:name :description])
                       (set/rename-keys {:name :title}))
        m (merge (spec-tools.impl/unwrap children)
                 extra-info
                 json-schema-meta)
        is-ref-arr (and (:items-ref json-schema-meta) (= "array" (:type m)))]

    (cond
      (:ref json-schema-meta) {"$ref" (:ref json-schema-meta)}

      is-ref-arr (-> m
                     (assoc :items {"$ref" (:items-ref json-schema-meta)})
                     (dissoc :items-ref))

      :else m)))