My slightly modified zsh shell

jnjosh.zsh-theme

# prompt style and colors based on Steve Losh's Prose theme:
# http://github.com/sjl/oh-my-zsh/blob/master/themes/prose.zsh-theme
#
# vcs_info modifications from Bart Trojanowski's zsh prompt:
# http://www.jukie.net/bart/blog/pimping-out-zsh-prompt
#
# git untracked files modification from Brian Carper:
# http://briancarper.net/blog/570/git-info-in-your-zsh-prompt

function virtualenv_info {
    [ $VIRTUAL_ENV ] && echo '('`basename $VIRTUAL_ENV`') '
}
PR_GIT_UPDATE=1

setopt prompt_subst
autoload colors
colors

autoload -U add-zsh-hook
autoload -Uz vcs_info

#use extended color pallete if available
if [[ $TERM = *256color* || $TERM = *rxvt* ]]; then
    turquoise="%F{81}"
    orange="%F{166}"
    purple="%F{135}"
    hotpink="%F{161}"
    limegreen="%F{118}"
else
    turquoise="$fg[cyan]"
    orange="$fg[yellow]"
    purple="$fg[magenta]"
    hotpink="$fg[red]"
    limegreen="$fg[green]"
fi

# enable VCS systems you use
zstyle ':vcs_info:*' enable git svn

# check-for-changes can be really slow.
# you should disable it, if you work with large repositories
zstyle ':vcs_info:*:prompt:*' check-for-changes true

# set formats
# %b - branchname
# %u - unstagedstr (see below)
# %c - stagedstr (see below)
# %a - action (e.g. rebase-i)
# %R - repository path
# %S - path in the repository
PR_RST="%{${reset_color}%}"
FMT_BRANCH="(%{$turquoise%}%b%u%c${PR_RST})"
FMT_ACTION="(%{$limegreen%}%a${PR_RST})"
FMT_UNSTAGED="%{$orange%}●"
FMT_STAGED="%{$limegreen%}●"

zstyle ':vcs_info:*:prompt:*' unstagedstr   "${FMT_UNSTAGED}"
zstyle ':vcs_info:*:prompt:*' stagedstr     "${FMT_STAGED}"
zstyle ':vcs_info:*:prompt:*' actionformats "${FMT_BRANCH}${FMT_ACTION}"
zstyle ':vcs_info:*:prompt:*' formats       "${FMT_BRANCH}"
zstyle ':vcs_info:*:prompt:*' nvcsformats   ""

function jnjosh_preexec {
    case "$(history $HISTCMD)" in
        *git*)
            PR_GIT_UPDATE=1
            ;;
        *svn*)
            PR_GIT_UPDATE=1
            ;;
    esac
}
add-zsh-hook preexec jnjosh_preexec

function jnjosh_chpwd {
    PR_GIT_UPDATE=1
}
add-zsh-hook chpwd jnjosh_chpwd

function jnjosh_precmd {
    if [[ -n "$PR_GIT_UPDATE" ]] ; then
        if git rev-parse --git-dir > /dev/null 2>&1; then

            now=`date +%s`
            last_commit=`git log --pretty=format:'%at' -1`
            seconds_since_last_commit=$((now-last_commit))
            
            minutes_since_last_commit=$((seconds_since_last_commit/60))
            hours_since_last_commit=$((minutes_since_last_commit/60))
            
            if [ $minutes_since_last_commit -gt 30 ]; then
                local COLOR=$orange
            elif [ $minutes_since_last_commit -gt 10 ]; then
                local COLOR=$limegreen
            else
                local COLOR=$orange
            fi

            if [ $minutes_since_last_commit -gt 60 ]; then 
                
                local SINCE_LAST_COMMIT="${hours_since_last_commit}h"                      
                if [ $hours_since_last_commit -gt 2 ]; then
                  local SINCE_LAST_COMMIT="2h+"                      
                fi
            else 
                local SINCE_LAST_COMMIT="${minutes_since_last_commit}m"            
            fi
        fi 
    
        # check for untracked files or updated submodules, since vcs_info doesn't
        if git ls-files --other --exclude-standard --directory 2> /dev/null | grep -q "."; then
            PR_GIT_UPDATE=1
            FMT_BRANCH="(%{$turquoise%}%b%u%c%{$hotpink%}●${PR_RST} - %{$COLOR%}${SINCE_LAST_COMMIT}${PR_RST})"
        else
            FMT_BRANCH="(%{$turquoise%}%b%u%c${PR_RST} - %{$COLOR%}${SINCE_LAST_COMMIT}${PR_RST})"
        fi
        
        zstyle ':vcs_info:*:prompt:*' formats       "${FMT_BRANCH}"

        vcs_info 'prompt'
        PR_GIT_UPDATE=
    fi
}
add-zsh-hook precmd jnjosh_precmd

PROMPT=$'
%{$orange%}%n%{$reset_color%} @ %{$turquoise%}%m%{$reset_color%} in %{$limegreen%}%~%{$reset_color%} $vcs_info_msg_0_
$(virtualenv_info)$ '

Very useful. Thanks for sharing 🙏