events.json

[
    {
        "name": "FlightBookedEvent",
        "values": [ "flight_code", "passenger_name", "cost" ]
    },
    {
        "name": "FlightCancelledEvent",
        "values": [ "flight_code", "passenger_name" ]
    }
]

Events.pm

module Events;
use JSON::Tiny;

package EXPORT::DEFAULT { }

my @events = @(from-json(slurp("events.json")));
for @events -> (:$name, :@values) {
    my $type := Metamodel::ClassHOW.new_type(:$name);
    for @values -> $attr_name {
        $type.HOW.add_attribute($type, Attribute.new(
            :name('$!' ~ $attr_name), :type(Mu),
            :has_accessor(1), :package($type)
        ));
    }
    $type.HOW.compose($type);
    EXPORT::DEFAULT.WHO{$name} := $type;
}

x.p6

use Events;

my $e1 = FlightBookedEvent.new(
    flight_code => 'AB123',
    passenger_name => 'jnthn',
    cost => 100);
say $e1.perl;

my $e2 = FlightCancelledEvent.new(
    flight_code => 'AB123',
    passenger_name => 'jnthn');
say $e2.flight_code;
say $e2.passenger_name;