Adding an optional param to string -> trim so that it works on any character.

string_trim.lasso

[
/**!
Lasso 9
Adding an optional param to string -> trim so that it works on any character.

Example
local(mypath = response_filepath)
#mypath -> trim('/')
#mypath
local(mystring = 'xxxräksmörgåsxx')
#mystring -> trim('x')
#mystring

Can also use an array
local(mystring = 'xzyräksmörgåsxyz')
#mystring -> trim(array('x','y','z'))
#mystring
**/
define string -> trim(trim::string) => {
	.removeleading(#trim) & .removetrailing(#trim)
}

// There is no string -> removetrailing(regexp) in the distro but there is a removeleading(regexp)
// This is a quick and dirty fix for that
define string -> removetrailing(find::regexp)=> {
	{
		.reverse
		#find->input = self
		if(!#find->matchesStart) => {
			.reverse
			return
		}
		.remove(1, #find->matchPosition->second)
		.reverse
		currentCapture->restart
	}()
}

define string -> trim(trim::array) => {
	if(#trim >> `|`) => {
		#trim -> removeall(`|`)
		#trim -> insert(`\|`)
	}
	local(remove = `(` + #trim -> join(`|`) + `)`)
	.removeleading(regexp(#remove)) & .removetrailing(regexp(#remove))
}

]