readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Candy Bomb
author Jonathan Brodsky
homepage www.jonbro.tk
noaction
color_palette amiga 

========
OBJECTS
========

Background
LIGHTBLUE

Wall
DarkBlue
(
PINK RED
.000.
00000
01000
01100
.000.
)
Player
Black Green Red Blue
.000.
02020
00000
.000.
.0.0.

PlayerShadow
Black
.....
.....
.....
.....
00000

PlayerDead
Grey blue
..0..
.000.
..0..
.101.
11111


Bomb0
Black brown
....1
...1.
.010.
.000.
.000.

Bomb1
Black Yellow brown
...1.
..2..
.020.
.000.
.000.

Bomb1Unlit
Black Yellow brown
.....
...2.
.020.
.000.
.000.

Bomb2
Black Yellow brown
.....
..1..
.020.
.000.
.000.

Bomb3
Black Yellow brown
.....
.....
.010.
.000.
.000.

Explosion
Red Yellow
1.1.1
.000.
10101
.000.
1.1.1

HardCandy
Red White
.010.
10101
10101
10101
.010.

Candy
Pink White
.010.
01001
10010
00100
.100.

CandyShatter
Pink White
..10.
01.01
.00.0
0.10.
.1.0.

=======
LEGEND
=======
Bomb = Bomb0 or Bomb1 or Bomb1Unlit or Bomb2 or Bomb3
Pushable =  Candy or HardCandy or Bomb
WinCandy = Candy or HardCandy
. = Background
# = Wall
P = Player
b = Bomb0
s = Bomb1unlit
c = Candy
h = HardCandy

=======
SOUNDS
=======

SFX0 21953904
SFX1 75575302

================
COLLISIONLAYERS
================

Background
PlayerShadow,
Player, Wall, Bomb, Candy, HardCandy, Explosion, PlayerDead, CandyShatter

======
RULES
====== 
[CandyShatter] -> []
late [ Player | Explosion ] -> [ PlayerDead | Explosion ]
late [ Candy | Explosion ] -> [ CandyShatter | Explosion ] sfx1
late [ Explosion | HardCandy | Explosion ] -> [ Explosion | CandyShatter | Explosion ] sfx1

late [ Explosion | Bomb2 ] -> [Explosion | Bomb3]
late [ Explosion | Bomb1 ] -> [Explosion | Bomb2]
late [ Explosion | Bomb1unlit ] -> [Explosion | Bomb2]
late [ Explosion | Bomb0 ] -> [Explosion | Bomb1]

[ Player] -> [Player PlayerShadow]
late [Player PlayerShadow] -> Cancel
late [PlayerShadow] -> []

[Explosion] -> []
[ Bomb3 ] -> [ Explosion ] sfx0
[ Bomb2 ] -> [ Bomb3 ]
[ Bomb1 ] -> [ Bomb2 ]

(clear the playershadow if we are against a bomb)
[ > Player PlayerShadow | Bomb0 ] -> [ > Player | > Bomb1 ]
[ > Player PlayerShadow | Bomb1unlit ] -> [ > Player | > Bomb2 ]
[ > Player PlayerShadow  | Bomb ] -> [ > Player PlayerShadow | > Bomb ]
(allow candies to push bombs)

startloop
[ > Player | Pushable ] -> [ > Player | > Pushable ]
[ > Pushable | Pushable ] -> [ > Pushable | > Pushable ]
endloop

==============
WINCONDITIONS
==============

no WinCandy
no PlayerDead

=======
LEVELS
=======

Message Destroy candy, stay alive 1/14

p
.
b
.
.
.
c

Message 2/14

bbbbp..
#####c.
#####..

Message 3/14

...#..
...#..
...bcp
...#..
...#..

Message 4/14

..c..
..p..
cbcbc
.b.b.

Message 5/14

####..##
####c..#
c....p..
#....b..
#.......

Message 6/14

####.
#.c.#
#cbc#
.bc..
#.#.p
.....

Message Some bombs have shorter fuses 7/14

.....
####.
c..sp
####.
.....

Message 8/14

.p.
...
.s.
ccc
...

Message 9/14

..p..
..c..
cscsc
..c..

Message 10/14

.......
.cccp..
.cscc#.
...b.s.
.ccc##.
.......

Message Hard candies need a bomb on each side to destroy 11/14

.....
##s.p
#bb#.
#b##.
#bb..
##h..
.#b..

Message 12/14

(correct parity offset from the top)
.....
.....
.s.c.
.s...
.s...
..s..
.#bp.
.bb..
.b#..
.bhb.

Message 13/14

(forking)

.........
....p.b..
..c..b...
..b.b.c..
..c..b...
...bh....
.........

Message 14/14

.........
.........
..b.sp...
..scccb..
...bh....
.........
.........

Message You have bombed all the candies