An Nft Minting Smart Contract

Readme.md

MyNFT

MyNFT is a ERC721 token contract written in Solidity. It is based on the OpenZeppelin framework and implements the IContent interface.

Features

MyNFT has the following features:

• GenerateNFT: This function allows users to generate a new NFT token, providing a name, description, and 6 uint256 values as Magic.
• setRenderingContractAddress: This function sets the address of the rendering contract, which is used to generate the token URI.
• setPrice: This function sets the price of generating a new NFT token.
• totalContent: This function returns the total number of NFT tokens generated.
• tokenURI: This function is used to query the URI of a token, using its token ID.
• withdraw: This function allows the owner of the contract to withdraw the funds held in the contract.

Events

MyNFT emits the following events:

• NewItem: This event is emitted when a new NFT token is generated. It contains the address of the sender, the token ID, and the name of the token.

MyNFTMinter.sol

// SPDX-License-Identifier: UNLICENSED

pragma solidity ^0.8.0;

import "@openzeppelin/contracts/utils/Strings.sol";
import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/Counters.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "./IContent.sol";

import "hardhat/console.sol";

contract MyNFT is ERC721, Ownable, ReentrancyGuard {
    using Counters for Counters.Counter;
    Counters.Counter private _tokenIds;
    mapping(uint256 => IContent.Item) Content;
    uint256 price = 5000000000000000;

    address public renderingContractAddress;

    event NewItem(address sender, uint256 tokenId, string name);

    constructor() ERC721("MYNFT", "MYCOLLECTION") {}

    function GenerateNFT(
        string calldata ItemName,
        string calldata description,
        uint256[6] calldata Magic
    ) public payable virtual {
        require(msg.value >= price, "Not enough ETH sent; check price!");

        uint256 newItemId = _tokenIds.current();

        if (newItemId >= 10000) {
            revert("This NFT is sold out.");
        }

        IContent.Item memory Item;

        Item.name = ItemName;
        Item.magic = Magic;

        Item.seed = uint256(
            keccak256(
                abi.encodePacked(
                    newItemId,
                    msg.sender,
                    block.difficulty,
                    block.timestamp
                )
            )
        );

        _safeMint(msg.sender, newItemId);

        Content[newItemId] = Item;

        emit NewItem(msg.sender, newItemId, ItemName);

        _tokenIds.increment();
    }

    function setRenderingContractAddress(address _renderingContractAddress)
        public
        onlyOwner
    {
        renderingContractAddress = _renderingContractAddress;
    }

    function setPrice(uint256 _price) public onlyOwner {
        price = _price;
    }

    function totalContent() public view virtual returns (uint256) {
        return _tokenIds.current();
    }

    function tokenURI(uint256 _tokenId)
        public
        view
        virtual
        override
        returns (string memory)
    {
        require(
            _exists(_tokenId),
            "ERC721Metadata: URI query for nonexistent token"
        );

        if (renderingContractAddress == address(0)) {
            return "";
        }

        IItemRenderer renderer = IItemRenderer(renderingContractAddress);
        return renderer.tokenURI(_tokenId, Content[_tokenId]);
    }

    function withdraw() public onlyOwner nonReentrant {
        (bool success, ) = msg.sender.call{value: address(this).balance}("");
        require(success, "Withdrawal failed");
    }
    
}