Alloy 6 code for a talk, "Wolf, Goat, & Cabbages In Two Styles!!", at !!Con West 2020

cabbages.als

abstract sig Object {
  eats: set Object,
  var location: one Riverbank
}

one sig Wolf extends Object {}
one sig Goat extends Object {}
one sig Cabbages extends Object {}
one sig Boat extends Object {}

fact foodWeb {
	eats = (Wolf -> Goat) + (Goat -> Cabbages)
}

abstract sig Riverbank {}

one sig EastBank extends Riverbank {}
one sig WestBank extends Riverbank {}

pred done {
	always location[Object] = WestBank // all objects are on the west bank
}

fact goals {
	historically location[Object] = EastBank  // all objects are on the east bank
	eventually done // eventually all together on the other side
}

fact safety {
	always no a: Object, b: a.eats |
		a.location = b.location and Boat.location != b.location
}

fact movement {
	{
 		let here = Boat.location, there = Boat.location' | {
			here != there
			some cargo: Object | {
				location' = location - (Boat -> here) - (cargo -> here)
				+ (Boat -> there) + (cargo -> there)
			}
		}
	} until done
}

run {} for 8