sensor.ino

#include "DHT.h"
#include <OneWire.h>
#include <ESP8266WiFi.h>
#include "Adafruit_MQTT.h"
#include "Adafruit_MQTT_Client.h"

#define DHTPIN D4
#define DHTTYPE DHT11

DHT dht(DHTPIN, DHTTYPE);

//---

OneWire  ds(D2);
byte type_s;
byte data[12];
byte addr[8];

//---

// WiFi configuration
//#define WLAN_SSID       "Andared"
//#define WLAN_PASS       "llevalatararaunvestidoblancollenodecascabeles"

// MQTT configuration
#define MQTT_SERVER      "test.mosquitto.org"
#define MQTT_SERVERPORT  1883

// WiFi configuration
#define WLAN_SSID       "Aula22"
#define WLAN_PASS       "mimamamemima"

//#define MQTT_SERVER      "192.168.22.99"
//#define MQTT_SERVERPORT  1883

#define MQTT_USERNAME    ""
#define MQTT_KEY         ""
#define MQTT_FEED_TEMP_DHT  "iescelia/aula22/temperature_dht"
#define MQTT_FEED_HUMI      "iescelia/aula22/humidity"
#define MQTT_FEED_TEMP_DS   "iescelia/aula22/temperature_ds"

// WiFi connection
WiFiClient client;

// MQTT connection
Adafruit_MQTT_Client mqtt(&client, MQTT_SERVER, MQTT_SERVERPORT, MQTT_USERNAME, MQTT_USERNAME, MQTT_KEY);

// Feed to publish temperature (dht11)
Adafruit_MQTT_Publish temperatureDHTFeed = Adafruit_MQTT_Publish(&mqtt, MQTT_FEED_TEMP_DHT);

// Feed to publish humidity
Adafruit_MQTT_Publish humidityFeed = Adafruit_MQTT_Publish(&mqtt, MQTT_FEED_HUMI);

// Feed to publish temperature (dht11)
Adafruit_MQTT_Publish temperatureDSFeed = Adafruit_MQTT_Publish(&mqtt, MQTT_FEED_TEMP_DS);

//----------------------------------------------

void connectWiFi() {
  WiFi.begin(WLAN_SSID, WLAN_PASS);
  while (WiFi.status() != WL_CONNECTED) {
     delay(500);
     Serial.print(".");
  }
}

//----------------------------------------------

void setup() {
  pinMode(D0, OUTPUT);
  
  Serial.begin(115200);
  Serial.println("IoT demo");
  dht.begin();
  initDS();
  connectWiFi();
  connectMQTT();
  digitalWrite(D0, HIGH);
}

//----------------------------------------------

void loop() {
  // Wait a few seconds between measurements.
  delay(3000);

  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius
  float t = dht.readTemperature();

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  float tds = getTemperatureFromDS();

  Serial.print("Humidity: ");
  Serial.print(h);
  Serial.print(" %\t");
  Serial.print("Temperature (DHT11): ");
  Serial.print(t);
  Serial.print(" *C\t");
  Serial.print("Temperature (DS): ");
  Serial.print(tds);
  Serial.println(" *C ");
 
  temperatureDHTFeed.publish(t);
  humidityFeed.publish(h);
  temperatureDSFeed.publish(tds);
}

//----------------------------------------------

void connectMQTT() {
  if (mqtt.connected())
    return;

  Serial.print("Connecting to MQTT... ");
  while (mqtt.connect() != 0) {
       Serial.println("Error. Retrying MQTT connection in 5 seconds...");
       mqtt.disconnect();
       delay(5000);
  }
  Serial.println("Connected. ");
}

//----------------------------------------------

void initDS() {
  byte i;
  
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }
  
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }

  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
 
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  } 

  ds.reset();
  ds.select(addr);
  ds.write(0x44, 1);        // start conversion, with parasite power on at the end
  
}

float getTemperatureFromDS() {
  byte i;
  byte present = 0;
  float celsius, fahrenheit;  
  
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
  
  present = ds.reset();
  ds.select(addr);    
  ds.write(0xBE);         // Read Scratchpad

  Serial.print("  Data = ");
  Serial.print(present, HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();

  // Convert the data to actual temperature
  // because the result is a 16 bit signed integer, it should
  // be stored to an "int16_t" type, which is always 16 bits
  // even when compiled on a 32 bit processor.
  int16_t raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // "count remain" gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    // at lower res, the low bits are undefined, so let's zero them
    if (cfg == 0x00) raw = raw & ~7;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
    //// default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");

  return celsius;
}