gistfile1.txt

PROJ	ENGLISH   CONFIG (1.0)
  ROOTCAT   S.
  FILES  .
  LEXENTRIES   (PROJ ENGLISH).
  RULES   (PROJ ENGLISH).
  TEMPLATES   (PROJ ENGLISH).
  GOVERNABLERELATIONS	SUBJ OBJ OBJ2 OBL OBL-?+ COMP XCOMP.
  SEMANTICFUNCTIONS	ADJUNCT  TOPIC.
  NONDISTRIBUTIVES	NUM PERS.
  EPSILON   e.
  OPTIMALITYORDER	 NOGOOD.


<comment>

	           Language Technologies Institute
	             Carnegie-Mellon University

*******************************************************************

 Copyright (c) 2013
 Carnegie Mellon University.  All Rights Reserved.

*******************************************************************

	 File Name: mlb.lfg
	Maintainer: Teruko Mitamura <teruko@cs.cmu.edu>
	   Created: 10-08-13  by Teruko
 Last Modified: 10-27-13  by Teruko
	   Version: Analyzer 1.0

*******************************************************************
 File Description:

 English analysis grammar for XLE
 LTI 11-721 Grammars and Lexicon

*******************************************************************
 Grammar Description:

 Feature structures:


</comment>



----
PROJ   ENGLISH   RULES (1.0)

S  -->
NP:
	(^ SUBJ) = !
	;
{VP:
	^ = !
|VbeP:
	^ = !
	(^ SUBJ NUM) = (! NUM)
	(^ SUBJ NUM) = (! OBJ NUM)
	(^ SUBJ ANIMATE) = (! OBJ ANIMATE)
|VPpassive:
	^ = !
	{@(UNKONWN_AGENT OBL)}
}
PP*:
	^ = !
	.

NP -->
(DET) N:
	^ = !
	.

VPpassive -->
Vbe (NOT) V:
	 ^ = !
	(! FORM) =c PP
	(! TYPE) ~= INTRANS;
(
NP:
	(^ OBJ) = !
)
.

VP -->
V:
	 ^ = !;
(
	{
	NP:
		(^ OBJ) = !
	|
	NP:
		(^ OBJ) = !;
	NP:
		(^ OBJ2) = !
	}
)
.

VbeP -->
{
Vbe:
	 ^ = !;
NP:
	(^ OBJ) = !
|
Vbe:
	^ = !
	{@(UNKONWN_AGENT OBJ)}
}
.

PP -->
{
	TO NP:
	{
	(^ LOCATIVE-TO) = !
	(^ LOCATIVE-TO FORM) = TO
	|
	(^ BENEFICIARY) = !
	(^ BENEFICIARY FORM) = TO
	}
|
	FOR NP:
	{
	(^ BENEFICIARY) = !
	(^ BENEFICIARY FORM) = FOR
	|
	(^ BENEFICIARY2) = !
	(^ BENEFICIARY2 FORM) = FOR
	(^ BENEFICIARY FORM) =c TO
	}
|
	IN NP:
	(^ LOCATIVE) = !
	(^ LOCATIVE FORM) = IN
	(! LOCATION) =c +
|
	BY NP:
	{
	(^ LOCATIVE-BY) = !
	(^ LOCATIVE-BY FORM) = BY
	(! LOCATION) =c +
	|
	(^ OBL) = !
	}
}
.

   ----
PROJ ENGLISH TEMPLATES (1.0)

V_NORM=
	(^ TENSE) = PRES
	(^ FORM) = NORM
	{
		{(^ SUBJ PERSON) = 1
		|(^ SUBJ PERSON) = 2
		|(^ SUBJ PERSON) = 3}
		(^ SUBJ NUM) = PL
	|
		{(^ SUBJ PERSON) = 1
		|(^ SUBJ PERSON) = 2}
		(^ SUBJ NUM) = SG
	}
	.

V_3SG=
	(^ TENSE) = PRES
	(^ SUBJ PERSON) = 3
	(^ SUBJ NUM) = SG
	.

V_PAST=
	(^ TENSE) = PAST
	(^ FORM) = PAST
	.

V_PP=
	(^ FORM) = PP
	.

V_TRANS(P S O)=
	(^ PRED) = 'P<(^ S)(^ O)>'
	(^ TYPE) = TRANS
	.

V_INTRANS(P S)=
	(^ PRED) = 'P<(^ S)>'
	(^ TYPE) = INTRANS
	.

V_DITRANS(P S O B)=
	(^ PRED)='P<(^ S) (^ O) (^ B)>'
	(^ TYPE) = DITRANS
	.

V_BE(S O)=
	{@(V_TRANS BE S O)
	|(^ AUX) = BE}
	.

COMMONSG(P)=
	(^ PRED) = 'P'
	(^ NUM) = SG
	(^ DEF)
	.
COMMONPL(P)=
	(^ PRED) = 'P'
	(^ NUM) = PL
	.

COMMONMS(P)=
	(^ PRED) = 'P'
	(^ NUM) = MASS
	.

PLACE=
	(^ ANIMATE) = -
	(^ LOCATION) = +
	(^ CANKILL) = -
	(^ CAN_RECIEVE) = +
	.

STUFF=
	(^ ANIMATE) = -
	(^ CAN_RECIEVE) = -
	(^ CANKILL) = +
	(^ LOCATION) = -
	.

PEOPLE=
	(^ ANIMATE) = +
	(^ CANKILL) = +
	(^ CAN_RECIEVE) = +
	(^ LOCATION) = -
	.

CAN_BE_KILLED(P)=
	(^ P ANIMATE) = +
	.

CAN_KILL(P)=
	(^ P CANKILL) = +
	.

KILL_CHECK(A P)=
	@(CAN_KILL A)
	@(CAN_BE_KILLED P)
	.

UNKONWN_AGENT(A)=
		(^ A PRED) = 'unknown'
.


   ----
PROJ ENGLISH LEXICON (1.0)

to	TO *
	.

for	FOR *
	.

in	IN *
	.

by	BY *
	.

not	NOT *
	(^ NAGATION) = +
	.

"Function words"

the	DET *
	(^ DEF) = +
	.

a	DET *
	(^ DEF) = -
	(^ NUM) = SG
	.

"Pronouns"

i	  N * (^ PRED) = 'pronoun'
	(^NUM) = SG
	~(^DEF)
	(^ ANIMATE) = +
	(^ PERSON) = 1
	.

we	  N * (^ PRED) = 'pronoun'
	(^NUM) = PL
	~(^DEF)
	(^ ANIMATE) = +
	(^ PERSON) = 1
	.

you	  N * (^ PRED) = 'pronoun'
	{(^NUM) = SG
	|(^NUM) = PL}
	~(^DEF)
	(^ ANIMATE) = +
	(^ PERSON) = 2
	.

he	  N * (^ PRED) = 'pronoun'
	(^NUM) = SG
	~(^DEF)
	(^ ANIMATE) = +
	(^ PERSON) = 3
	.

it	  N * (^ PRED) = 'pronoun'
	(^NUM) = SG
	~(^DEF)
	(^ ANIMATE) = -
	(^ PERSON) = 3
	.

they	  N * (^ PRED) = 'pronoun'
	(^NUM) = PL
	~(^DEF)
	(^ ANIMATE) = +
	(^ PERSON) = 3
	.


"Named Entities"

"Nouns"

teacher	N * @(COMMONSG TEACHERS)
	@PEOPLE
	.

teachers	N * @(COMMONPL TEACHERS)
	@PEOPLE
	.

ball	N * @(COMMONSG BALL)
	@STUFF
	.

balls	N *  @(COMMONPL BALL)
	@STUFF
	.

money	N * @(COMMONMS MONEY)
	@STUFF
	.

city	N * @(COMMONSG CITY)
	@PLACE
	.

cities	N * @(COMMONPL CITY)
	@PLACE
	.

park	N * @(COMMONSG PARK)
	@PLACE
	.

parks	N * @(COMMONPL PARK)
	@PLACE
	.


"BE Verbs"

is	Vbe * @(V_BE SUBJ OBJ)
	@V_3SG
	.

am	Vbe * @(V_BE SUBJ OBJ)
	(^ TENSE) = PRES
	(^ SUBJ NUM) = SG
	(^ SUBJ PERSON) = 1
	.

are	Vbe * @(V_BE SUBJ OBJ)
	(^ TENSE) = PRES
	{(^ SUBJ PERSON) = 2
	|(^ SUBJ PERSON) = 1
	 (^ SUBJ NUM) = PL
	|(^ SUBJ PERSON) = 3
	 (^ SUBJ NUM) = PL
	}
	.

was	Vbe * @(V_BE SUBJ OBJ)
	(^ TENSE) = PAST
	(^ SUBJ NUM) = SG
	{
		(^ SUBJ PERSON) = 1
	|	(^ SUBJ PERSON) = 3
	}
	.

were	Vbe * @(V_BE SUBJ OBJ)
	(^ TENSE) = PAST
	{
		(^ SUBJ NUM) = SG
		(^ SUBJ PERSON) = 2
	|
		(^ SUBJ NUM) = PL
	}
	.

"Verbs intrans"

run	V * @(V_INTRANS RUN SUBJ)
	(^ SUBJ ANIMATE) = +
	(^ BENEFICIARY FORM) ~= TO
	@V_NORM
	.

runs	V * @(V_INTRANS RUN SUBJ)
	(^ SUBJ ANIMATE) = +
	(^ BENEFICIARY FORM) ~= TO
	@V_3SG
	.

ran	V * @(V_INTRANS RUN SUBJ)
	(^ SUBJ ANIMATE) = +
	(^ BENEFICIARY FORM) ~= TO
	@V_PAST
	.

"Verbs trans"

kill	V * @(V_TRANS KILL SUBJ OBJ)
	@(KILL_CHECK SUBJ OBJ)
	@V_NORM
	.

kills	V * @(V_TRANS KILL SUBJ OBJ)
	@(KILL_CHECK SUBJ OBJ)
	@V_3SG
	.

killed	V *
	{
	@(V_TRANS KILL SUBJ OBJ)
	@(KILL_CHECK SUBJ OBJ)
	@V_PAST
	|
	@(V_TRANS KILL OBL SUBJ)
	@(KILL_CHECK OBL SUBJ)
	@V_PP
	}
	.

"Verbs ditrans"

give	V * {@(V_DITRANS GIVE SUBJ OBJ2 OBJ)
	         (^ OBJ CAN_RECIEVE) = +
	        |@(V_DITRANS GIVE SUBJ OBJ BENEFICIARY)
	         (^ BENEFICIARY FORM) = TO
	         (^ BENEFICIARY CAN_RECIEVE) = +}
	(^ SUBJ ANIMATE) = +
	(^ LOCATIVE-TO FORM) ~= TO
	@V_NORM
	.

gives	V * {@(V_DITRANS GIVE SUBJ OBJ2 OBJ)
	         (^ OBJ CAN_RECIEVE) = +
	        |@(V_DITRANS GIVE SUBJ OBJ BENEFICIARY)
	         (^ BENEFICIARY FORM) = TO
	         (^ BENEFICIARY CAN_RECIEVE) = +}
	(^ SUBJ ANIMATE) = +
	(^ LOCATIVE-TO FORM) ~= TO
	@V_3SG
	.

gave	V * {@(V_DITRANS GIVE SUBJ OBJ2 OBJ)
	         (^ OBJ CAN_RECIEVE) = +
	        |@(V_DITRANS GIVE SUBJ OBJ BENEFICIARY)
	         (^ BENEFICIARY FORM) = TO
	         (^ BENEFICIARY CAN_RECIEVE) = +}
	(^ SUBJ ANIMATE) = +
	(^ LOCATIVE-TO FORM) ~= TO
	@V_PAST
	.

gave	V * {@(V_DITRANS GIVE SUBJ OBJ2 OBJ)
	         (^ OBJ CAN_RECIEVE) = +
	        |@(V_DITRANS GIVE SUBJ OBJ BENEFICIARY)
	         (^ BENEFICIARY FORM) = TO
	         (^ BENEFICIARY CAN_RECIEVE) = +}
	(^ SUBJ ANIMATE) = +
	(^ LOCATIVE-TO FORM) ~= TO
	@V_PAST
	.

given	V * @(V_DITRANS GIVE OBL OBJ SUBJ)
	(^ LOCATIVE-TO FORM) ~= TO
	@V_PP
	.

"Adverbs"


----