Build Nix Package from Flake

README.md

Testing Nix Packages

To test a nix package derivation, drop the flake.nix into the directory of the default.nix and temporarily add it to the local clone of the nixpkgs git repository.

$ git add --intent-to-add flake.nix

Then, to build the package and use the output in a dev shell:

$ nix develop
...
(nix:nix-shell-env) $

flake.nix

{
  description = "build target package";

  inputs = {
    target = {
      url = "path:default.nix";
      flake = false;
    };
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    systems.url = "github:nix-systems/default";
  };

  outputs =
    {
      systems,
      nixpkgs,
      ...
    }@inputs:
    let
      inherit (nixpkgs) lib;

      overlays = [
        (
          final: prev:
          let
            pkgs = nixpkgs.legacyPackages.${prev.system};
          in
          {
            target = pkgs.callPackage inputs.target { };
          }
        )
      ];

      eachSystem =
        f:
        lib.genAttrs (import systems) (
          system:
          f (
            import nixpkgs {
              inherit system overlays;
            }
          )
        );
    in
    {
      devShells = eachSystem (pkgs: {
        default = pkgs.mkShell {
          packages = with pkgs; [
            target
          ];
        };
      });
      packages = eachSystem (pkgs: {
        default = pkgs.target;
      });
    };
}