Export an HTML table to a CSV file using HTMl5 Blob object, with data URI fallback

jquery.export_to_csv.js.coffee

$.fn.exportToCsv = ->
  export_element = $( $(this).data('export-target') )
  csv_string = csvStringFrom(export_element)

  if Blob
    $(this).prop(
      download: csvFilename(),
      href: URL.createObjectURL(new Blob([csv_string], type: 'text/csv'))
    )
  else
    data_uri_header = 'data:text/csv;charset=UTF-8,'
    window.location =  data_uri_header + encodeURIComponent(csv_string)

csvFilename = (prefix = "export") ->
  date = new Date()
  date_parts = [
    date.getFullYear(),
    date.getMonth(),
    date.getDay(),
    date.getHours(),
    date.getMinutes()
  ]

  ([prefix].concat date_parts).join('-') + ".csv"

csvStringFrom = (element) ->
  if element.is('table')
    csv = ""
    headers = []
    body = []

    element.find('thead > tr > th').each ->
      headers.push($(this).text())

    element.find('tbody > tr').each ->
      row = []
      $(this).find('td').each ->
        row.push $(this).text()

      body.push(row.join(','))

    if headers.length
      csv += (headers.join(",") + "\n")

    csv += body.join("\n")

    return csv
  else
    element.text()

$ ->
  $('a#export-report').click ->
    $(this).exportToCsv()