Build script for Subversion on Windows x64

build.cmd

@REM
@REM Top-directory/
@REM   httpd/                   .... Apache Lounge Distribution / Apache 2.4.x win64 VS16
@REM     Apache24/
@REM       include/
@REM         expat_external.h   .... https://github.com/libexpat/libexpat/raw/R_2_2_9/expat/lib/expat_external.h
@REM   py3c/                    .... https://github.com/encukou/py3c
@REM     include/
@REM     py3c.pc.in
@REM   sqlite/                  .... SQLite amalgamation
@REM   swig3/                   .... SWIG 3.0.12 binary
@REM     swig.exe
@REM   zlib/                    .... libzlib-1.2.11-msvc2017-amd64-release
@REM     include/
@REM     lib/
@REM   trunk/                   .... trunk
@REM   1.14.x/                  .... branches/1.14.x
@REM   build.cmd                .... (this file)
@REM

@setlocal
@set _DIR_=%~dp0
python.exe -V || exit/b 1
awk.exe --version || exit/b 1
@call "%ProgramFiles(x86)%\Microsoft Visual Studio\2019\Community\Common7\Tools\VsDevCmd.bat"
@set "INCLUDE=%ProgramFiles%\Microsoft SDK\include;%INCLUDE%"
@set "LIB=%ProgramFiles%\Microsoft SDK\lib;%LIB%"
REM rmdir/s/q build\win32\vcnet-vcproj
REM del gen-make.opts
python.exe gen-make.py ^
    --vsnet-version=2019 ^
    --with-apr=%_DIR_%httpd\Apache24 ^
    --with-apr-util=%_DIR_%httpd\Apache24 ^
    --with-zlib=%_DIR_%zlib ^
    --with-sqlite=%_DIR_%sqlite ^
    --with-swig=%_DIR_%swig3 ^
    --with-py3c=%_DIR_%py3c
msbuild subversion_vcnet.sln ^
    /fl ^
    /flp:logfile=%_DIR_%build.log ^
    /m:1 ^
    /p:BuildInParallel=false ^
    /t:__MORE__ ^
    /t:__SWIG_PYTHON__ ^
    /p:Configuration=Release ^
    /p:Platform=x64
@endlocal