昔でっちあげたもの - リストファイル内IPへPingかけて、結果をテキストファイルへ書き出すバッチファイル

ping_tester.bat

:: 2009
::pingテスト用バッチファイル

@echo off
::pingオプションを指定
set timeout=30
set count=5

::ファイル名を指定
set file_list=listfile.txt

::試験概要
set manage_summary=pingtest

::↓こっから先は基本固定

::dateを整形し、変数fname_dateへ埋め込み
set fname_date=%date:~-10,4%%date:~-5,2%%date:~-2,2%

::timeを整形し、変数fname_time2へ埋め込み
set fname_time1=%time: =0%
::set fname_time2=%fname_time1:~0,2%%fname_time1:~3,2%%fname_time1:~6,2%
set fname_time2=%fname_time1:~0,2%%fname_time1:~3,2%

::ファイル名等へ利用する為の、日付+時刻文字列を取得
set fname_dateandtime=%fname_date%-%fname_time2%

::確認用 >> echo %fname_date%
::確認用 >> echo %fname_time2%
::確認用 >> echo %fname_dateandtime%

::ログファイル名を生成
set fname=%manage_summary%_%fname_dateandtime%.log

::確認用 >> echo %fname%

::ヘッダーを吐き出す。
echo 概要：	%manage_summary%>>%fname%
echo タイムアウト、回数：	%timeout%、%count%>>%fname%
echo ソースIP：	>>%fname%

ipconfig>>%fname%

::pingを実施
echo はじまりはじまり


FOR /F "delims=" %%a IN (%file_list%) DO (
	echo ------------------------------------------------------------->>%fname%
	echo 開始時刻：%date%%time%>>%fname%
	echo %%a　へ%manage_summary%を実施中・・・
	echo 試験対象：%%a>>%fname%
	ping -w %timeout% -n %count% %%a>>%fname%
	echo 終了時刻：%date%%time%>>%fname%
	echo ------------------------------------------------------------->>%fname%
	)

echo おしまい！
echo 試験結果は、「%fname%」に保存しました。

pause