Windows 10/11 Setup Script

win10repair.bat

@echo off

@rem "This little script sets a few useful settings in Windows 10 that most"
@rem "serious users are likely to want; scroll through the script for details"
@rem "and disable sections you don't want."

@rem "Usage:"
@rem "Just save this file as a .bat or .cmd file and run it (with"
@rem "Administrator privileges!). You will need to re-run it after larger"
@rem "updates, as these tend to overwrite some of the settings or re-create"
@rem "files that are deliberately deleted by the script."
@rem "As a rule of thumb, re-run the script when the 'desktop.ini' icon"
@rem "reappears on the desktop."

@rem "First, some hints to settings that are *not* set by this script."

@rem "Win11: give this script permission to disable 'Start' and 'Catalog' in the Explorer:"
@rem "- regedit, right-click on HKCR\CLSID\{f874310e-..., permissions, advanced, change owner to Administrators"
@rem "  and also give Administrators full access"
@rem "- same for CLSID\{e88865ea-... and HKCR\WOW6432Node\CLSID\..."

@rem "Allow symlink creation:"
@rem "- secpol.msc -> Local Policies -> User Rights Assignment -> Create symbolic links"
@rem "  -> add 'Everybody'"

@rem "Autologin:"
@rem "- HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\PasswordLess\Device\DevicePasswordLessBuildVersion = 0"
@rem "- run netplwiz, uncheck "users must logon with pwd", click OK, enter password one last time"

@rem "Configure Desktop icons:"
@rem "- Settings -> Personalization -> Themes -> Related Settings -> Desktop icon settings"

@rem "Get rid of "Camera Roll" and "Saved Pictures":"
@rem "- Configure them away in %APPDATA%/Microsoft/Windows/Libraries"

@rem "Tame Defender: [MIGHT BE OUTDATED]"
@rem "- HKLM\Software\Policies\Microsoft\Windows Defender\DisableRoutinelyTakingAction:DWORD=1"

@rem "Repair Windows Spotlight:"
@rem "- Settings -> Privacy -> Background apps -> [X] Allow apps to run,"
@rem "  but unselect all *except* Microsoft Edge and Settings"

@echo ***** checking administrator privileges
net file >nul 2>nul
@if errorlevel 1 (
    @echo This script should be run with administrator privileges.
    @echo Press ^^C and Y now or close this window to exit,
    @echo or press Enter to continue without administrator privileges.
    @pause
)
@echo.

@echo ***** make Explorer windows open This PC instead of Quick Access
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v LaunchTo /t REG_DWORD /d 1 /f /reg:32
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v LaunchTo /t REG_DWORD /d 1 /f /reg:64
@echo.

@echo ***** disable thumbnails in Explorer
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v IconsOnly /t REG_DWORD /d 1 /f /reg:32
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v IconsOnly /t REG_DWORD /d 1 /f /reg:64
@echo.

@echo ***** show hidden files in Explorer
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v Hidden /t REG_DWORD /d 1 /f /reg:32
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v Hidden /t REG_DWORD /d 1 /f /reg:64
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v ShowSuperHidden /t REG_DWORD /d 1 /f /reg:32
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v ShowSuperHidden /t REG_DWORD /d 1 /f /reg:64
@echo.

@echo ***** show file extensions in Explorer
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v HideFileExt /t REG_DWORD /d 0 /f /reg:32
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v HideFileExt /t REG_DWORD /d 0 /f /reg:64
@echo.

@echo ***** open Explorer windows in separate processes
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v SeparateProcess /t REG_DWORD /d 0 /f /reg:32
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v SeparateProcess /t REG_DWORD /d 0 /f /reg:64
@echo.

@echo ***** use standard context menus in Win11 Explorer
reg add HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32 /ve /d "" /f /reg:32
reg add HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32 /ve /d "" /f /reg:64
@echo.

@echo ***** hide OneDrive from Explorer
reg add HKCR\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0 /f /reg:32
reg add HKCR\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0 /f /reg:64
@rem "similar for Dropbox, if desired: UUID starts with E31EA727"
@echo.

@echo ***** hide WSL2 from Explorer
reg add HKCR\CLSID\{B2B4A4D1-2754-4140-A2EB-9A76D9D7CDC6} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0 /f /reg:32
reg add HKCR\CLSID\{B2B4A4D1-2754-4140-A2EB-9A76D9D7CDC6} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0 /f /reg:64
@echo.

@echo ***** hide Catalog from Explorer (Win11)
reg add HKCR\CLSID\{e88865ea-0e1c-4e20-9aa6-edcd0212c87c} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0 /f /reg:32
reg add HKCR\CLSID\{e88865ea-0e1c-4e20-9aa6-edcd0212c87c} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0 /f /reg:64
@echo.

@echo ***** hide Start from Explorer (Win11)
reg add HKCR\CLSID\{f874310e-b6b7-47dc-bc84-b9e6b38f5903} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0 /f /reg:32
reg add HKCR\CLSID\{f874310e-b6b7-47dc-bc84-b9e6b38f5903} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0 /f /reg:64
@echo.

@echo ***** hide removable drives from Explorer top-level
reg delete HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Desktop\NameSpace\DelegateFolders\{F5FB2C77-0E2F-4A16-A381-3E560C68BC83} /f /reg:32
reg delete HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Desktop\NameSpace\DelegateFolders\{F5FB2C77-0E2F-4A16-A381-3E560C68BC83} /f /reg:64
@echo.

@echo ***** remove folder shortcuts from This PC
@rem Pictures
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{0ddd015d-b06c-45d5-8c4c-f59713854639}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:32
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{0ddd015d-b06c-45d5-8c4c-f59713854639}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:64
@rem Videos
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{35286a68-3c57-41a1-bbb1-0eae73d76c95}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:32
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{35286a68-3c57-41a1-bbb1-0eae73d76c95}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:64
@rem Downloads
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{7d83ee9b-2244-4e70-b1f5-5393042af1e4}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:32
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{7d83ee9b-2244-4e70-b1f5-5393042af1e4}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:64
@rem Music
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{a0c69a99-21c8-4671-8703-7934162fcf1d}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:32
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{a0c69a99-21c8-4671-8703-7934162fcf1d}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:64
@rem Desktop
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{B4BFCC3A-DB2C-424C-B029-7FE99A87C641}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:32
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{B4BFCC3A-DB2C-424C-B029-7FE99A87C641}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:64
@rem Documents
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{f42ee2d3-909f-4907-8871-4c22fc0bf756}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:32
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{f42ee2d3-909f-4907-8871-4c22fc0bf756}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:64
@rem 3D Objects
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{31C0DD25-9439-4F12-BF41-7FF4EDA38722}\PropertyBag /f /reg:32
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{31C0DD25-9439-4F12-BF41-7FF4EDA38722}\PropertyBag /f /reg:64
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{31C0DD25-9439-4F12-BF41-7FF4EDA38722}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:32
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FolderDescriptions\{31C0DD25-9439-4F12-BF41-7FF4EDA38722}\PropertyBag /v ThisPCPolicy /t REG_SZ /d Hide /f /reg:64
@echo.

@echo ***** Disable web search in Start Menu
reg add HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Search /v BingSearchEnabled /t REG_DWORD /d 0 /f
reg add HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Search /v AllowCortana /t REG_DWORD /d 0 /f
reg add HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Search /v CortanaConsent /t REG_DWORD /d 0 /f
@echo.

@echo ***** remove desktop.ini from Desktop
del /ah /f %USERPROFILE%\Desktop\desktop.ini %PUBLIC%\Desktop\desktop.ini
@echo.

echo ***** remove desktop.ini from customized default folders (to avoid localization)
@rem Note: We only do that if the user deliberately moved the folder out of
@rem       their profile folder, under the assumption that they did that to
@rem       choose their own name for these folders, and that they don't want
@rem       the names to be mangled by Explorer.
@rem Documents
powershell -Command "$x=[Environment]::GetFolderPath('Personal');if(-not $x.StartsWith($env:UserProfile)){Remove-Item -LiteralPath (Join-Path $x desktop.ini) -Force -ErrorAction SilentlyContinue}"
@rem Downloads (can't use GetFolderPath here, and PS doesn't have a SHGetKnownFolderPath wrapper either, so we have to use the registry)
powershell -Command "$x=(Get-ItemProperty -Path 'HKCU:\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders').'{374DE290-123F-4565-9164-39C4925E467B}';if(-not $x.StartsWith($env:UserProfile)){Remove-Item -LiteralPath (Join-Path $x desktop.ini) -Force -ErrorAction SilentlyContinue}"
@rem (My) Pictures
powershell -Command "$x=[Environment]::GetFolderPath('MyPictures');if(-not $x.StartsWith($env:UserProfile)){Remove-Item -LiteralPath (Join-Path $x desktop.ini) -Force -ErrorAction SilentlyContinue}"
@rem (My) Music
powershell -Command "$x=[Environment]::GetFolderPath('MyMusic');if(-not $x.StartsWith($env:UserProfile)){Remove-Item -LiteralPath (Join-Path $x desktop.ini) -Force -ErrorAction SilentlyContinue}"
@rem (My) Video
powershell -Command "$x=[Environment]::GetFolderPath('MyVideo');if(-not $x.StartsWith($env:UserProfile)){Remove-Item -LiteralPath (Join-Path $x desktop.ini) -Force -ErrorAction SilentlyContinue}"

@echo ***** restore fully functional printing dialog
reg add HKCU\Software\Microsoft\Print\UnifiedPrintDialog /v PreferLegacyPrintDialog /t REG_DWORD /d 1 /f /reg:32
reg add HKCU\Software\Microsoft\Print\UnifiedPrintDialog /v PreferLegacyPrintDialog /t REG_DWORD /d 1 /f /reg:64

@echo ***** disable automatic reboot after bluescreen
reg add HKLM\System\CurrentControlSet\Control\CrashControl /v AutoReboot /t REG_DWORD /d 0 /f
@echo ***** give full error information in bluescreens
reg add HKLM\System\CurrentControlSet\Control\CrashControl /v DisplayParameters /t REG_DWORD /d 1 /f
@echo.

@echo ***** disable System Volume Information folder creation on removable media
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows /v DisableRemovableDriveIndexing /t REG_DWORD /d 1 /f
@echo.

@echo ***** disable automatic driver download
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\DriverSearching /v SearchOrderConfig /t REG_DWORD /d 0 /f
@echo.

@echo ***** disable reboot on automatic updates
@rem cf. https://docs.microsoft.com/en-us/windows/deployment/update/waas-restart
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /v AUOptions /t REG_DWORD /d 4 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /v NoAutoRebootWithLoggedOnUsers /t REG_DWORD /d 1 /f
@echo.

@echo ***** disable Virtualization Based Security / Core Isolation
reg add HKLM\SOFTWARE\CurrentControlSet\CurrentControlSet\Control\DeviceGuard\Scenarios\HypervisorEnforcedCodeIntegrity /v Enabled /t REG_DWORD /d 0 /f
@echo.

@echo ***** disable Hybrid Shutdown
reg add "HKLM\System\CurrentControlSet\Control\Session Manager\Power" /v HiberbootEnabled /t REG_DWORD /d 0 /f
@rem "or manually: Win+X -> Power Options -> Related Settings -> Additional Power Settings"
@rem "             -> Choose what the power button does [Sidebar]"
@rem "             -> Change settings that are currently unavailable [Shield]"
@rem "             -> disable 'Turn on fast startup (recommended)'"
@echo.

@echo ***** uninstall third-party shovelware
powershell -Command "Get-AppxPackage king.com.CandyCrushSaga | Remove-AppxPackage"
powershell -Command "Get-AppxPackage king.com.CandyCrushSodaSaga | Remove-AppxPackage"
powershell -Command "Get-AppxPackage ShazamEntertainmentLtd.Shazam | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Flipboard.Flipboard | Remove-AppxPackage"
powershell -Command "Get-AppxPackage 9E2F88E3.Twitter | Remove-AppxPackage"
powershell -Command "Get-AppxPackage ClearChannelRadioDigital.iHeartRadio | Remove-AppxPackage"
powershell -Command "Get-AppxPackage D5EA27B7.Duolingo-LearnLanguagesforFree | Remove-AppxPackage"
powershell -Command "Get-AppxPackage AdobeSystemsIncorporated.AdobePhotoshopExpress | Remove-AppxPackage"
powershell -Command "Get-AppxPackage PandoraMediaInc.29680B314EFC2 | Remove-AppxPackage"
powershell -Command "Get-AppxPackage 46928bounde.EclipseManager | Remove-AppxPackage"
powershell -Command "Get-AppxPackage ActiproSoftwareLLC.562882FEEB491 | Remove-AppxPackage"
powershell -Command "Get-AppxPackage SpotifyAB.SpotifyMusic | Remove-AppxPackage"
@echo.

@echo ***** uninstall Photos app
@rem Reason: On older Windows 10 versions, it frequently hogged the CPU and disks
@rem         in futile attempts to index all images on the PC.
powershell -Command "Get-AppxPackage *photos* | Remove-AppxPackage"
@echo.

@echo ***** uninstall other unneeded Microsoft apps
powershell -Command "Get-AppxPackage Microsoft.OutlookForWindows | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Clipchamp.Clipchamp | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.3DBuilder | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.BingNews | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.BingWeather | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.BingSports | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.BingFinance | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.Office.Sway | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.WindowsPhone | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.CommsPhone | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.YourPhone | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.Getstarted | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.549981C3F5F10 | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.Messaging | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.WindowsFeedbackHub | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.WindowsAlarms | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.People | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.Wallet | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.Print3D | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.OneConnect | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.MicrosoftStickyNotes | Remove-AppxPackage"
powershell -Command "Get-AppxPackage microsoft.windowscommunicationsapps | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.SkypeApp | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.GroupMe10 | Remove-AppxPackage"
powershell -Command "Get-AppxPackage Microsoft.Todos | Remove-AppxPackage"
@echo.

@echo ***** removing ModifiableWindowsApps from secondary drive
@rem some checking is done to assure that it's really an empty directory
if not exist "D:\Program Files\ModifiableWindowsApps" goto noMWA
dir /a /b "D:\Program Files\ModifiableWindowsApps\*" | findstr "^" >nul && goto noMWA
takeown /f "D:\Program Files\ModifiableWindowsApps"
takeown /f "D:\Program Files"
icacls "D:\Program Files\ModifiableWindowsApps" /reset
rmdir "D:\Program Files\ModifiableWindowsApps"
rmdir "D:\Program Files"
:noMWA
@echo.

@echo ***** uninstall OneDrive
taskkill /f /im OneDrive.exe
@if errorlevel 1 goto noonedrive
%SystemRoot%\SysWOW64\OneDriveSetup.exe /uninstall
:noonedrive
rmdir "%UserProfile%\OneDrive" /Q /S
rmdir "%LocalAppData%\Microsoft\OneDrive" /Q /S
rmdir "%ProgramData%\Microsoft\OneDrive" /Q /S
rmdir "C:\OneDriveTemp" /Q /S
@echo.

@echo ***** disable Windows 11 ads
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\CloudContent /v DisableWindowsConsumerFeatures /t REG_DWORD /d 1 /f
reg add HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v ShowSyncProviderNotifications /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v Start_IrisRecommendations /t REG_DWORD /d 0 /f
reg add HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v ContentDeliveryAllowed /d 0 /t REG_DWORD /f
reg add HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v OemPreInstalledAppsEnabled /d 0 /t REG_DWORD /f
reg add HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v PreInstalledAppsEnabled /d 0 /t REG_DWORD /f
reg add HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v PreInstalledAppsEverEnabled /d 0 /t REG_DWORD /f
reg add HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v SilentInstalledAppsEnabled /d 0 /t REG_DWORD /f
reg add HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v SystemPaneSuggestionsEnabled /d 0 /t REG_DWORD /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v RotatingLockScreenOverlayEnabled /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v SubscribedContent-338387Enabled /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v SubscribedContent-338393Enabled /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v SubscribedContent-353694Enabled /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v SubscribedContent-353696Enabled /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v SubscribedContent-338389Enabled /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\ContentDeliveryManager /v SubscribedContent-310093Enabled /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\UserProfileEngagement /v ScoobeSystemSettingEnabled /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\AdvertisingInfo /v Enabled /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Privacy /v TailoredExperiencesWithDiagnosticDataEnabled /t REG_DWORD /d 0 /f
@echo.

@echo ***** disable Taskbar Widgets
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v TaskbarDa /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v ShowTaskViewButton /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Microsoft\PolicyManager\default\NewsAndInterests\AllowNewsAndInterests /v value /t REG_DWORD /d 0 /f
reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\Windows Feeds" /v EnableFeeds /t REG_DWORD /d 0 /f
@echo.

@echo ***** disable Copilot and Recall
reg add HKCU\Software\Policies\Microsoft\Windows\WindowsCopilot /v TurnOffWindowsCopilot /t REG_DWORD /d 1 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Notifications\Settings /v AutoOpenCopilotLargeScreens /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v ShowCopilotButton /t REG_DWORD /d 0 /f
reg add HKCU\Software\Microsoft\Windows\Shell\Copilot\BingChat /v IsUserEligible /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v HubsSidebarEnabled /t REG_DWORD /d 0 /f
powershell -Command "Get-AppxPackage Microsoft.CoPilot | Remove-AppxPackage"
dism /Online /Disable-Feature /FeatureName:Recall
@echo.

@echo ***** remove bloat from Edge
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v EdgeEnhanceImagesEnabled /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v PersonalizationReportingEnabled /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v ShowRecommendationsEnabled /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v HideFirstRunExperience /t REG_DWORD /d 1 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v UserFeedbackAllowed /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v ConfigureDoNotTrack /t REG_DWORD /d 1 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v AlternateErrorPagesEnabled /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v EdgeCollectionsEnabled /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v EdgeFollowEnabled /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v EdgeShoppingAssistantEnabled /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v MicrosoftEdgeInsiderPromotionEnabled /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v ShowMicrosoftRewards /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v WebWidgetAllowed /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v DiagnosticData /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v EdgeAssetDeliveryServiceEnabled /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v CryptoWalletEnabled /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Edge /v WalletDonationEnabled /t REG_DWORD /d 0 /f
@echo.

@rem @echo ***** disable Home Groups (only relevant for pre-1803 versions)
@rem sc config HomeGroupProvider start= disabled
@rem sc stop HomeGroupProvider
@rem @echo.

@echo ***** disable Telemetry
sc config DiagTrack start= disabled
sc stop DiagTrack
sc config diagnosticshub.standardcollector.service start=demand
sc config diagsvc start=demand
sc config WerSvc start=demand
sc config wercplsupport start=demand
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\DataCollection /v AllowTelemetry /t REG_DWORD /d 0 /f
reg add HKLM\Software\Policies\Microsoft\Windows\DataCollection /v DisableOneSettingsDownloads /t REG_DWORD /d 1 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\DataCollection /v AllowDesktopAnalyticsProcessing /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\DataCollection /v AllowDeviceNameInTelemetry /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\DataCollection /v MicrosoftEdgeDataOptIn /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\DataCollection /v AllowWUfBCloudProcessing /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\DataCollection /v AllowUpdateComplianceProcessing /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\DataCollection /v AllowCommercialDataPipeline /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\DataCollection /v AllowTelemetry /t REG_DWORD /d 0 /f
reg add HKLM\Software\Policies\Microsoft\SQMClient\Windows /v CEIPEnable /t REG_DWORD /d 0 /f
reg add HKCU\Software\Policies\Microsoft\Windows\EdgeUI /v DisableMFUTracking /t REG_DWORD /d 1 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\System /v PublishUserActivities /t REG_DWORD /d 0 /f
reg add "HKLM\Software\Policies\Microsoft\Windows NT\CurrentVersion\Software Protection Platform" /v NoGenTicket /t REG_DWORD /d 1 /f
reg add "HKLM\Software\Policies\Microsoft\Windows\Windows Error Reporting" /v Disabled /t REG_DWORD /d 1 /f
reg add "HKLM\SOFTWARE\Microsoft\Windows\Windows Error Reporting" /v Disabled /t REG_DWORD /d 1 /f
reg add "HKLM\Software\Microsoft\Windows\Windows Error Reporting\Consent" /v DefaultConsent /t REG_DWORD /d 0 /f
reg add "HKLM\Software\Microsoft\Windows\Windows Error Reporting\Consent" /v DefaultOverrideBehavior /t REG_DWORD /d 1 /f
reg add "HKLM\Software\Microsoft\Windows\Windows Error Reporting" /v DontSendAdditionalData /t REG_DWORD /d 1 /f
reg add "HKLM\Software\Microsoft\Windows\Windows Error Reporting" /v LoggingDisabled /t REG_DWORD /d 1 /f
reg add HKCU\Software\Microsoft\VisualStudio\Telemetry /v TurnOffSwitch /t REG_DWORD /d 1 /f
@echo.

@echo ***** disable Unfair Commercial Practices Directive driver (requires restart)
sc config UCPD start= disabled
schtasks /change /Disable /TN "\Microsoft\Windows\AppxDeploymentClient\UCPD velocity"
@echo.

@echo ***** disable cursor animations in Office 365
reg add HKCU\SOFTWARE\Microsoft\Office\16.0\Common\Graphics /v DisableAnimations /t REG_DWORD /d 1 /f
@echo.

@echo ***** disable display change animation
reg add HKLM\SOFTWARE\Microsoft\Windows\Dwm /v ForceDisableModeChangeAnimation /t REG_DWORD /d 1 /f
@echo.

@echo.
@echo Will now close all Explorer windows and restart Explorer.
@echo Press ^^C and Y now or close this window to avoid that.
@pause
taskkill /f /im explorer.exe
start explorer.exe
:end