Android NDK build script for Gradle. GradleでNDKビルドをするスクリプト。

ndkbuild.gradle

// ndkbuild.gradle

def useJar = true // libをJar化するかどうか
def jniDir = 'src/main/jni'

android {
    sourceSets {
        main {
            jni.srcDirs = []
            jniLibs.srcDirs = useJar ? [] : [new File(buildDir, 'libs')]
        }
    }
}

task ndkBuild(type: Exec) {
    def ndkDir = project.plugins.findPlugin('android').getNdkFolder()
    commandLine "${ndkDir}/ndk-build",
            "NDK_PROJECT_PATH=build",
            "APP_BUILD_SCRIPT=${jniDir}/Android.mk",
            "NDK_APPLICATION_MK=${jniDir}/Application.mk"
}

task ndkLibsToJar(type: Zip, dependsOn: 'ndkBuild') {
    destinationDir new File(buildDir, 'libs')
    baseName 'nativelibs'
    extension 'jar'
    from(new File(buildDir, 'libs')) { include '**/*.so' }
    into 'lib/'
}

tasks.withType(AbstractCompile) {
    compileTask -> compileTask.dependsOn useJar ? ndkLibsToJar : ndkBuild
}

dependencies {
    compile fileTree(dir: new File(buildDir, 'libs'), include: '*.jar')
}

usage example

// in build.gradle

apply plugin: 'android'
apply from: './ndkbuild.gradle'

...

// in local.properties

ndk.dir=path/to/ndk/root/directory

...