Attean algebra pattern matching

attean-pattern-matching.pl

#!/usr/bin/env perl

use v5.14;
use Attean;
use Attean::Algebra qw(match);

my $algebra	= Attean->get_parser('SPARQL')->parse(<<"END");
SELECT * WHERE {
	?s ?p ?o
	FILTER(ISLITERAL(?o))
}
END

say $algebra->as_string;
# - Query
# -   Project { ?o ?s ?p }
# -     Filter { ISLITERAL(?o) }
# -       BGP { ?s ?p ?o . }



# Now, try to match the algebra against the pattern Query(Project(*)), and pull
# out the child of the Project.
my $pattern	= Attean::Algebra::Query->new(
	children	=> [
		Attean::Algebra::Project->new(
			children	=> [
				# if we successfully match the pattern, store this part of the
				# algebra tree with the name 'graphpattern'
				match('graphpattern'),
			],
			
			# Only 'children' are matched, so this is here only to stop the
			# Attean::Algebra::Project constructor from complaining about
			# missing build args.
			variables	=> [],
		)
	]
);

if (my $matches = $algebra->match($pattern)) {
	say "The child algebra of Project:";
	say $matches->{'graphpattern'}->as_string;
	# The child algebra of Project:
	# - Filter { ISLITERAL(?o) }
	# -   BGP { ?s ?p ?o . }
}