switcher.ahk

;; # RightClick + WheelUp
;; Switch between 2 virtual desktops back and forth
;;
;; # RightClick + WheelDown
;; Triggers Alt+Tab (previous window back and forth)
;; Triggers Alt+Shift+Tab (cycle windows) when scrolling

#Requires AutoHotkey v2.0

global forward := true
global lastUp := 0
global lastDown := 0
debounceUp := 600
debounceDown := 150
cycleWindow := 900

RButton::RButton

RButton & WheelUp:: {
    global forward, lastUp, lastDown

    now := A_TickCount

    if (now - lastDown < cycleWindow) {
        Send("!{Tab}")
        lastDown := now
        return
    }

    if (now - lastUp < debounceUp)
        return

    if forward
        Send("^#{Right}")
    else
        Send("^#{Left}")

    lastUp := now
    forward := !forward
}

RButton & WheelDown:: {
    global lastDown

    now := A_TickCount
    if (now - lastDown < debounceDown)
        return

    if (now - lastDown < cycleWindow)
        Send("!+{Tab}")
    else
        Send("!{Tab}")

    lastDown := now
}