ESC (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title ESC
author Kenny Goff
homepage www.kennygoff.com

NOACTION

========
OBJECTS
========

Background
WHITE BLACK
11111
10001
10001
10001
11111

Boundary
BLACK
00000
00000
00000
00000
00000

Path
LIGHTBLUE
.....
.000.
.000.
.000.
.....

PathBroken
RED
0...0
.0.0.
..0..
.0.0.
0...0

Player
BLUE
.....
.000.
.000.
.000.
.....

Exit
GREEN
.000.
0...0
0...0
0...0
.000.

Key
YELLOW
.....
..0..
.000.
..0..
.....

Wall
DARKGRAY
00000
00000
00000
00000
00000

WallCollapsed
LIGHTGRAY
00000
00000
00000
00000
00000

Portal
PURPLE
.....
.000.
.0.0.
.000.
.....


Switch
DARKGRAY LIGHTGRAY
.....
.010.
.101.
.010.
.....

Platform
LIGHTGRAY
00000
00000
00000
00000
00000

PlatformExpanded
DARKGRAY
00000
00000
00000
00000
00000

StepperLeft
PINK
.....
.0...
.00..
.0...
.....

StepperRight
PINK
.....
...0.
..00.
...0.
.....

StepperDown
PINK
.....
.....
..0..
.000.
.....

StepperUp
PINK
.....
.000.
..0..
.....
.....

=======
LEGEND
=======

. = Background
! = Boundary
; = Path
P = Player
E = Exit
K = Key
# = Wall
% = Platform
@ = Portal
S = Switch
L = StepperLeft
R = StepperRight
D = StepperDown
U = StepperUp
F = StepperRight and Exit

=======
SOUNDS
=======

EndLevel 8907905
PathBroken Create 24015904
Sfx0 41726504

================
COLLISIONLAYERS
================

Background
WallCollapsed, Platform
Switch
Exit
Key
Portal
Wall, PlatformExpanded, Boundary, Player
Path
StepperLeft
StepperRight
StepperDown
StepperUp
PathBroken

======
RULES
======

(Stepper)
	(Left)
[ StepperLeft ] -> [ LEFT StepperLeft ]
late [ StepperLeft Player ] -> [ StepperLeft Player PathBroken ]
[ > StepperLeft | Boundary ] -> [ StepperLeft | Boundary ]
[ > StepperLeft | Wall ] -> [ StepperLeft | Wall ]
[ > StepperLeft | PlatformExpanded ] -> [ StepperLeft | PlatformExpanded ]
([ > StepperLeft | Path ] -> [ StepperLeft | Path ])
([ > StepperLeft | Player ] -> [ StepperLeft | Player ])
[ > StepperLeft | < Player ] -> [ StepperLeft | < Player ]
	(Right)
[ StepperRight ] -> [ RIGHT StepperRight ]
late [ StepperRight Player ] -> [ StepperRight Player PathBroken ]
[ > StepperRight | Boundary ] -> [ StepperRight | Boundary ]
[ > StepperRight | Wall ] -> [ StepperRight | Wall ]
[ > StepperRight | PlatformExpanded ] -> [ StepperRight | PlatformExpanded ]
([ > StepperRight | Path ] -> [ StepperRight | Path ])
([ > StepperRight | Player ] -> [ StepperRight | Player ])
[ > StepperRight | < Player ] -> [ StepperLeft | < Player ]
	(Down)
[ StepperDown ] -> [ DOWN StepperDown ]
late [ StepperDown Player ] -> [ StepperDown Player PathBroken ]
[ > StepperDown | Boundary ] -> [ StepperDown | Boundary ]
[ > StepperDown | Wall ] -> [ StepperDown | Wall ]
[ > StepperDown | PlatformExpanded ] -> [ StepperDown | PlatformExpanded ]
([ > StepperDown | Path ] -> [ StepperDown | Path ])
([ > StepperDown | Player ] -> [ StepperDown | Player ])
[ > StepperDown | < Player ] -> [ StepperLeft | < Player ]
	(Up)
[ StepperUp ] -> [ UP StepperUp ]
late [ StepperUp Player ] -> [ StepperUp Player PathBroken ]
[ > StepperUp | Boundary ] -> [ StepperUp | Boundary ]
[ > StepperUp | Wall ] -> [ StepperUp | Wall ]
[ > StepperUp | PlatformExpanded ] -> [ StepperUp | PlatformExpanded ]
([ > StepperUp | Path ] -> [ StepperUp | Path ])
([ > StepperUp | Player ] -> [ StepperUp | Player ])
[ > StepperUp | < Player ] -> [ StepperLeft | < Player ]
	(Resolve Collision)
LEFT [ StepperLeft | Boundary ] -> [ RIGHT StepperRight | Boundary ]
LEFT [ StepperLeft | Wall ] -> [ RIGHT StepperRight | Wall ]
LEFT [ StepperLeft | PlatformExpanded ] -> [ RIGHT StepperRight | PlatformExpanded ]
(LEFT [ StepperLeft | Path ] -> [ RIGHT StepperRight | Path ])
(LEFT [ StepperLeft | Player ] -> [ RIGHT StepperRight | Player ])
RIGHT [ StepperRight | Boundary ] -> [ LEFT StepperLeft | Boundary ]
RIGHT [ StepperRight | Wall ] -> [ LEFT StepperLeft | Wall ]
RIGHT [ StepperRight | PlatformExpanded ] -> [ LEFT StepperLeft | PlatformExpanded ]
(RIGHT [ StepperRight | Path ] -> [ LEFT StepperLeft | Path ])
(RIGHT [ StepperRight | Player ] -> [ LEFT StepperLeft | Player ])
DOWN [ StepperDown | Boundary ] -> [ UP StepperUp | Boundary ]
DOWN [ StepperDown | Wall ] -> [ UP StepperUp | Wall ]
DOWN [ StepperDown | PlatformExpanded ] -> [ UP StepperUp | PlatformExpanded ]
(DOWN [ StepperDown | Path ] -> [ UP StepperUp | Path ])
(DOWN [ StepperDown | Player ] -> [ UP StepperUp | Player ])
UP [ StepperUp | Boundary ] -> [ DOWN StepperDown | Boundary ]
UP [ StepperUp | Wall ] -> [ DOWN StepperDown | Wall ]
UP [ StepperUp | PlatformExpanded ] -> [ DOWN StepperDown | PlatformExpanded ]
(UP [ StepperUp | Path ] -> [ DOWN StepperDown | Path ])
(UP [ StepperUp | Player ] -> [ DOWN StepperDown | Player ])

(Player Path)
[ > Player | Path ] -> CANCEL
[ > Player | Boundary ] -> CANCEL
[ > Player | Wall ] -> CANCEL
[ > Player | PlatformExpanded ] -> CANCEL
[ > Player | No Path No Wall ] -> [ Path | Player ]

(Keys)
[ Player Key ] -> [ Player ]

(Portals)
late [ Player Portal ][ No Player Portal ] -> [ Path ][ Player ]

(Switches)
[ Player Switch ][ Platform ] -> [ Player Switch ][ PlatformExpanded ]
[ Player Switch ][ Wall ] -> [ Player Switch ][ WallCollapsed ]
[ Player Switch ] -> [ Player ]
late [ PlatformExpanded Path ] -> [ PlatformExpanded PathBroken ]
(late [ PlatformExpanded Path ] -> CANCEL)

(Broken Paths)
[ PathBroken ] -> CANCEL

==============
WINCONDITIONS
==============

All Player on Exit
No Key
(No Path on PlatformExpanded)
No PathBroken

=======
LEVELS
=======

MESSAGE Hello, P.L.A.Y.E.R., let's begin.

(1-5)

..P..
.....
.....
.....
..E..

P....
.....
.....
.....
....E

#.P.#
#...#
#.#.#
#...#
#.E.#

P....
.#.#.
.....
.#.#.
....E

MESSAGE Hmm, you're faster than I calculated...

P....
.....
.....
.....
E...K

(6-10)

P.E..
.#.#.
K.K.K
.#.#.
..K.K

.KP##
KKKE#
.K.##
.K.##
.K.##

#EP.#
#K..#
#.#.#
#...#
#K..#

MESSAGE You won't survive this round in one piece!

..P..
..@..
.....
..@..
##E##

P###@
.###.
.###.
.###.
@###E

(11-15)

P..K@
.#.#.
.K@..
.#.#.
E....

P...@
.#.#.
..@..
.#K#.
....E

.KP##
@K@E#
.K.##
.K.##
.K.##

#.P.#
#...#
#@#K#
#...#
#KE@#

MESSAGE Escape is binary and you will not succeed!

.....
#####
P....
%%%%%
E....

(16-20)

E....
#####
P...S
%%%%%
.....

P#...
.#.#.
S..#.
K#K#K
.#..E

P....
.#.#.
K.K.K
K%K%S
....E

...#.
.%.#.
.%.#.
.%.#.
P%S#E

MESSAGE This can't be... Code R.E.D.! Engaging V.I.R.U.S. Protocol!

!!!!!!!
!..E..!
!R....!
!....L!
!.....!
!..P..!
!!!!!!!

(21-25)

!!!!!!!
!#E..#!
!#.R.#!
!#.#.#!
!#...#!
!#P..#!
!!!!!!!

!!!!!!!
!P....!
!.#D..!
!..L..!
!...#.!
!....E!
!!!!!!!

!!!!!!!
!P....!
!..D#.!
!..L.L!
!.#..L!
!....E!
!!!!!!!

MESSAGE Wait where are you going?

!!!!!!!
!P...L!
[email protected].!
!#####!
!.LS.@!
!.....!
!!!!!!!

MESSAGE This isn't possible, I will stop you!

!!!!!!!
!.R.F.!
!P###@!
!.US..!
!@%%%.!
!.....!
!!!!!!!

MESSAGE NOOOoo...

MESSAGE [K.A.R.E.N. Powering down]

MESSAGE P.L.A.Y.E.R. Successful

MESSAGE P.L.A.Y.E.R. Test Phase One... Complete