nkf-2.1.0.ebuild

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit toolchain-funcs eutils perl-module distutils

DESCRIPTION="Network Kanji code conversion Filter with UTF-8/16 support"
HOMEPAGE="http://sourceforge.jp/projects/nkf/"
SRC_URI="mirror://sourceforge.jp/nkf/44486/${P}.tar.gz
        python? ( http://city.plala.jp/moin/NkfPython?action=AttachFile&do=get&target=NKF_python20090602.tgz -> NKF_python20090602.tgz )"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="perl python linguas_ja"

src_unpack() {
        unpack ${P}.tar.gz

        cd "${S}"

        sed -i -e '/-o nkf/s:$(CFLAGS):$(CFLAGS) $(LDFLAGS):' Makefile || die

        if use python; then
                unpack NKF_python20090602.tgz
                # bug #248725
                sed -i -e "s/-s/${CFLAGS}/" NKF.python/setup.py || die
        fi
}

src_compile() {
        emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}" nkf || die
        if use perl; then
                cd "${S}/NKF.mod"
                perl-module_src_compile
        fi
        if use python; then
                cd "${S}/NKF.python"
                distutils_src_compile
        fi
}

src_test() {
        emake test || die
        if use perl; then
                cd "${S}/NKF.mod"
                perl-module_src_test
        fi
}

src_install() {
        dobin nkf || die
        doman nkf.1
        if use linguas_ja; then
                ./nkf -e nkf.1j > nkf.1
                doman -i18n=ja nkf.1
        fi
        dodoc nkf.doc
        if use perl; then
                cd "${S}/NKF.mod"
                perl-module_src_install
        fi
        if use python; then
                cd "${S}/NKF.python"
                distutils_src_install
        fi
}