This is a PKGBUILD script to create a tdom package that is compatible with tcl 8.6 (see https://aur.archlinux.org/packages/tdom/)

PKGBUILD.tdom-git

# Maintainer: Uwe Koloska <[email protected]>
# Contributor: Dejan Cabrilo <[email protected]>

pkgname=tdom-git
pkgver=20130121
pkgrel=1
pkgdesc="A fast XML/DOM/XPath package for Tcl written in C"
arch=('i686' 'x86_64')
url="http://tdom.github.com/"
license=('MPL')
groups=('devel')
depends=('expat' 'tcl')
makedepends=('git')
conflicts=('tdom')
provides=('tdom')

_gitroot=https://github.com/tDOM/tdom.git
_gitname="tdom"

build() {
  cd "${srcdir}"

  msg "Connecting to GIT server..."
  if [[ -d "${_gitname}" ]]; then
    cd "${_gitname}" && git pull origin
    msg "The local files are updated."
  else
    git clone --depth=1 "${_gitroot}" "${_gitname}"
  fi
  msg "GIT checkout done or server timeout"

  msg "Starting make..."

  cd "${srcdir}"
  rm -rf "${_gitname}-build"
  git clone "${_gitname}" "${_gitname}-build"

  cd "${srcdir}/${_gitname}-build"

  if [ $CARCH = "x86_64" ] ; then
    ./configure --prefix=/usr --enable-64bit --mandir=/usr/share/man
  else
    ./configure --prefix=/usr --mandir=/usr/share/man
  fi
  make
}

package() {
  make -C "${srcdir}/$_gitname-build" DESTDIR="$pkgdir/" install
}

incorporate the changes suggested by Daniel Wallace (but leaving the subshell around 'git pull')

update with changes suggested by Limao Luo