Computation Expression with Dependency Injection

Program.fs

module Program

open Microsoft.Extensions.DependencyInjection
open Microsoft.Extensions.Logging

type ResultBuilder(logger:ILogger<ResultBuilder>) =
   member _.Return x = Ok(x)
   member _.ReturnFrom (m:Result<_, _>) = m
   member _.Bind (m, f) = Result.bind f m
   member _.Delay f =
      match f () with
      | Ok(_) as m -> m
      | Error(error) as m -> logger.LogError(sprintf "Error occurred: '%A'" error); m

let services =
   ServiceCollection()
      .AddLogging(fun builder ->
         builder
            .AddFilter("*", LogLevel.Debug)
            .AddConsole()
         |> ignore
      )
      .AddSingleton<ResultBuilder>()

[<EntryPoint>]
let main argv =
   use sp = services.BuildServiceProvider()
   let result = sp.GetRequiredService<ResultBuilder>()
   let res1 : Result<string, string> = result {
      let! a = Ok("hoge")
      let! b = Ok("fuga")
      return a + b
   }
   let res2 : Result<string, string> = result {
      let! a = Ok("foo")
      let! b = Error("bar")
      return a + b
   }
   printfn "%A %A" res1 res2
   0