sop-based generic editor

Buildable.hs

{-# LANGUAGE FlexibleContexts, MultiParamTypeClasses, GADTs, DefaultSignatures, DeriveAnyClass, StandaloneDeriving, ScopedTypeVariables, TypeApplications #-}
module Buildable where

import Generics.SOP
import Generics.SOP.Metadata

class Buildable a where
  build :: IO a
  default build :: (Generic a, HasDatatypeInfo a, All2 Buildable (Code a)) => IO a
  build = gbuild

instance Buildable Int where
  build = do
    putStrLn $ "Provide integer:"
    readLn

gbuild :: forall a . (Generic a, HasDatatypeInfo a, All2 Buildable (Code a)) => IO a
gbuild = do
  putStrLn $ "Select a constructor: " ++ show (zip [0..] (conNames (Proxy @a)))
  n <- readLn
  to <$> choose' n

choose' :: (All SListI xss, All2 Buildable xss) => Int -> IO (SOP I xss)
choose' n = map hsequence (apInjs_POP (hcpure (Proxy @Buildable) build)) !! n

conNames :: (SListI (Code a), HasDatatypeInfo a) => Proxy a -> [String]
conNames p = hcollapse (hmap (K . constructorName) (constructorInfo (datatypeInfo p)))

deriving instance Buildable Bool
deriving instance Buildable a => Buildable [a]

{-

> gbuild :: IO (Either Int [Bool])
Select a constructor: [(0,"Left"),(1,"Right")]
0
Provide integer:
5
Left 5

> gbuild :: IO (Either Int [Bool])
Select a constructor: [(0,"Left"),(1,"Right")]
1
Select a constructor: [(0,"[]"),(1,":")]
1
Select a constructor: [(0,"False"),(1,"True")]
1
Select a constructor: [(0,"[]"),(1,":")]
1
Select a constructor: [(0,"False"),(1,"True")]
0
Select a constructor: [(0,"[]"),(1,":")]
0
Right [True,False]

-}