Arch Linux AUR PKGBUILD for lilyterm-git

PKGBUILD

# Maintainer : koyudoon <koyudoon at gmail dot com>

# Contributors by way of lilyterm package in arch repos
# Contributor: Kyle Keen <[email protected]>
# Contributor: TDY <[email protected]>
# Contributor: DonVla <[email protected]>
# Contributor: Stefan Husmann <[email protected]>

pkgname=lilyterm-git
provides=('lilyterm')
pkgver=0.9.9.4.r96.g7f1b524
pkgrel=1
pkgdesc='A light and easy to use libvte based X terminal emulator'
arch=('i686' 'x86_64')
url='http://lilyterm.luna.com.tw/index_en.html'
license=('GPL3')
depends=('vte')
conflicts=('lilyterm')
makedepends=('gettext' 'intltool' 'pkgconfig>=0.16')
source=("${pkgname%-git}::git+https://github.com/Tetralet/LilyTerm")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/${pkgname%-git}"
  git describe --long --tags | sed -E 's/([^-]*-g)/r\1/;s/-/./g;s/^v//'
}

build() {
  cd "$srcdir/${pkgname%-git}"
  ./configure --prefix=/usr \
              --sysconfdir=/etc
  make
}

package() {
  cd "$srcdir/${pkgname%-git}"
  make DESTDIR="$pkgdir" install
}