PKGBUILD for aur/python-indexed-gzip 1.10.1

PKGBUILD

# -*- sh -*-

#  Maintainer: Tobias Bachmann <[email protected]>
# Contributor: Klaus Alexander Seistrup <$(echo 0x1fd+d59decfa=40 | tr 0-9+a-f=x [email protected])>

pkgname=python-indexed-gzip
pkgver=1.10.1
pkgrel=1
pkgdesc='Fast random access of gzip files in Python'
_name=indexed_gzip
arch=('aarch64' 'x86_64')
url="https://github.com/pauldmccarthy/indexed_gzip"
license=('BSD-3-Clause')
depends=(
  'glibc'
  'python'
  'zlib'
)
makedepends=(
  'cython'
  'python-build'
  'python-installer'
  'python-setuptools'
  'python-wheel'
)
options=(!emptydirs)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('f38744bc9e23c80329ff7d3af719ac8b80c511622206a9594125b797eb00ed01')

build() {
  cd "$srcdir/$_name-$pkgver"

  export SETUPTOOLS_SCM_PRETEND_VERSION="$pkgver"
  python -m build --wheel --no-isolation
}

package() {
  cd "$srcdir/$_name-$pkgver"

  python -m installer --destdir="$pkgdir/" dist/*.whl

  local _site='---INVALID---'
  _site=$(python -c 'import site; print(site.getsitepackages()[0])')

  rm -vfr "$pkgdir$_site/indexed_gzip/tests/"
  rm -vf  "$pkgdir$_site/indexed_gzip/"*.{c,h,pxd,pyx}

  install -vDm0644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
  install -vDm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}

# eof