PGKBUILD for aur/somo v1.3.1

PKGBUILD

# Maintainer: David Birks <[email protected]>
# Contributor: Klaus Alexander Seistrup <$(echo 0x1fd+d59decfa=40 | tr 0-9+a-f=x [email protected])>

pkgname=somo
pkgver=1.3.1
pkgrel=1
pkgdesc='A human-friendly alternative to netstat for socket and port monitoring'
url='https://github.com/theopfr/somo'
license=('MIT')
makedepends=('cargo')
depends=('gcc-libs' 'glibc')
arch=('x86_64')
source=("$pkgname-$pkgver.tar.gz::https://github.com/theopfr/somo/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('89476469318f3cc9d334ed39f415d0638d79df265929c05a27acb9a372544cc8')
options=('!debug')

prepare() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --frozen --release --all-features
    for _shell in bash elvish fish zsh; do
        target/release/somo generate-completions "$_shell" > "_completions.$_shell"
    done
}

check() {
    cd "$pkgname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    cargo test --frozen --all-features
}

package() {
    cd "$pkgname-$pkgver"
    install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/somo"
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
    install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
    install -Dm0644 _completions.bash \
        "$pkgdir/usr/share/bash-completion/completions/somo"
    install -Dm0644 _completions.elvish \
        "$pkgdir/usr/share/elvish/lib/somo.elv"
    install -Dm0644 _completions.fish \
        "$pkgdir/usr/share/fish/vendor_completions.d/somo.fish"
    install -Dm0644 _completions.zsh \
        "$pkgdir/usr/share/zsh/site-functions/_somo"
}