"Inherit" from CL_CI_TEST_ABAP_NAMING_NEW

zcl_ci_naming.abap

class ZCL_CI_NAMING definition
  public
  inheriting from CL_CI_TEST_INCLUDE
  final
  create public .

public section.

  methods CONSTRUCTOR .

  methods CLEAR
    redefinition .
  methods GET_ATTRIBUTES
    redefinition .
  methods GET_MESSAGE_TEXT
    redefinition .
  methods IF_CI_TEST~QUERY_ATTRIBUTES
    redefinition .
  methods PUT_ATTRIBUTES
    redefinition .
  methods RUN
    redefinition .
protected section.
private section.

  data MO_NAMING_NEW type ref to CL_CI_TEST_ABAP_NAMING_NEW .
  constants C_MY_NAME type SEOCLSNAME value 'ZCL_CI_NAMING_NEW'. "#EC NOTEXT

  methods HANDLER
    for event MESSAGE of CL_CI_TEST_ROOT
    importing
      !SENDER
      !P_SUB_OBJ_TYPE
      !P_SUB_OBJ_NAME
      !P_LINE
      !P_COLUMN
      !P_ERRCNT
      !P_KIND
      !P_TEST
      !P_CODE
      !P_PARAM_1
      !P_SUPPRESS
      !P_PARAM_2
      !P_PARAM_3
      !P_PARAM_4
      !P_CHECKSUM_1
      !P_INCLSPEC
      !P_DETAIL .
ENDCLASS.



CLASS ZCL_CI_NAMING IMPLEMENTATION.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_CI_NAMING->CLEAR
* +-------------------------------------------------------------------------------------------------+
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD CLEAR.

    mo_naming_new->clear( ).

  ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_CI_NAMING->CONSTRUCTOR
* +-------------------------------------------------------------------------------------------------+
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD constructor.

* not possible to inherit from CL_CI_TEST_ABAP_NAMING_NEW since it is defined as final

    super->constructor( ).

    CREATE OBJECT mo_naming_new.
    SET HANDLER handler FOR mo_naming_new.

    description       = 'New Naming Standard'.
    category          = 'ZCL_CI_CATEGORY'.

    has_attributes    = 'X'.
    attributes_ok     = 'X'.

  ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_CI_NAMING->GET_ATTRIBUTES
* +-------------------------------------------------------------------------------------------------+
* | [<-()] P_ATTRIBUTES                   TYPE        XSTRING
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD GET_ATTRIBUTES.

    p_attributes = mo_naming_new->get_attributes( ).

  ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_CI_NAMING->GET_MESSAGE_TEXT
* +-------------------------------------------------------------------------------------------------+
* | [--->] P_TEST                         TYPE        CLIKE
* | [--->] P_CODE                         TYPE        CLIKE
* | [<---] P_TEXT                         TYPE        CLIKE
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD GET_MESSAGE_TEXT.

    mo_naming_new->get_message_text(
      EXPORTING
        p_test = 'CL_CI_TEST_ABAP_NAMING_NEW'
        p_code = p_code
      IMPORTING
        p_text = p_text ).

  ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Private Method ZCL_CI_NAMING->HANDLER
* +-------------------------------------------------------------------------------------------------+
* | [--->] SENDER                         LIKE
* | [--->] P_SUB_OBJ_TYPE                 LIKE
* | [--->] P_SUB_OBJ_NAME                 LIKE
* | [--->] P_LINE                         LIKE
* | [--->] P_COLUMN                       LIKE
* | [--->] P_ERRCNT                       LIKE
* | [--->] P_KIND                         LIKE
* | [--->] P_TEST                         LIKE
* | [--->] P_CODE                         LIKE
* | [--->] P_PARAM_1                      LIKE
* | [--->] P_SUPPRESS                     LIKE
* | [--->] P_PARAM_2                      LIKE
* | [--->] P_PARAM_3                      LIKE
* | [--->] P_PARAM_4                      LIKE
* | [--->] P_CHECKSUM_1                   LIKE
* | [--->] P_INCLSPEC                     LIKE
* | [--->] P_DETAIL                       LIKE
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD HANDLER.

    inform(
        p_sub_obj_type = p_sub_obj_type
        p_sub_obj_name = p_sub_obj_name
        p_line         = p_line
        p_column       = p_column
        p_errcnt       = p_errcnt
        p_kind         = p_kind
        p_test         = c_my_name
        p_code         = p_code
        p_param_1      = p_param_1
        p_param_2      = p_param_2
        p_param_3      = p_param_3
        p_param_4      = p_param_4
        p_inclspec     = p_inclspec
        p_detail       = p_detail
        p_checksum_1   = p_checksum_1 ).

  ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_CI_NAMING->IF_CI_TEST~QUERY_ATTRIBUTES
* +-------------------------------------------------------------------------------------------------+
* | [--->] P_DISPLAY                      TYPE        FLAG (default =' ')
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD IF_CI_TEST~QUERY_ATTRIBUTES.

    mo_naming_new->if_ci_test~query_attributes( p_display ).

  ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_CI_NAMING->PUT_ATTRIBUTES
* +-------------------------------------------------------------------------------------------------+
* | [--->] P_ATTRIBUTES                   TYPE        XSTRING
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD PUT_ATTRIBUTES.

    mo_naming_new->put_attributes( p_attributes ).

  ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method ZCL_CI_NAMING->RUN
* +-------------------------------------------------------------------------------------------------+
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD run.

    IF ref_include->trdir-cdat >= '20140701'.
      mo_naming_new->run( ).
    ENDIF.

  ENDMETHOD.
ENDCLASS.