aws-cli-v2 PKGBUILD

PKGBUILD

pkgname=aws-cli-v2
pkgver=2.0.4
pkgrel=1
pkgdesc='Universal Command Line Interface for Amazon Web Services version 2'
arch=('i686' 'x86_64')
url='https://docs.aws.amazon.com/cli/latest/userguide/install-cliv2.html'
license=('Apache')
provides=('aws-cli')
conflicts=('aws-cli')
makedepends=('python-setuptools')
depends=('less' \
         'python-botocore-v2-git' \
         'python-docutils' \
         'python-s3transfer' \
         'python-ruamel-yaml' \
         'python-prompt_toolkit' \
         'python-colorama')
source=(
  "$pkgname-$pkgver.tar.gz::https://github.com/aws/aws-cli/archive/${pkgver}.tar.gz"
)
sha256sums=('377c48c90228196704c229ea7111332f4dac131419722213bf55d4075ae94a0b')

build() {
  cd "$srcdir/aws-cli-$pkgver"

  python setup.py build
}

package() {
  cd "$srcdir/aws-cli-$pkgver"

  python setup.py install --root="$pkgdir" --optimize=1

  install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/"$pkname"/LICENSE
  install -Dm644 bin/aws_bash_completer "$pkgdir"/usr/share/bash-completion/completions/aws

  rm -f "$pkgdir"/usr/bin/{aws.cmd,aws_bash_completer}
}

First of all, thanks for this!

Works almost perfectly...

...in Manjaro I got this error:

ModuleNotFoundError: No module named 'cryptography'

Added package python-cryptography and it fixed it. Might want to add it as a dependency here as well.