Enable Diagnostic logs on an Azure storage account with terraform

storagediagnosticlogs.tf

resource "random_string" "random" {
  length  = 5
  special = false
  upper   = false
  number  = false
}

resource "azurerm_log_analytics_workspace" "core" {
  name                = "corelaw${random_string.random.result}"
  location            = "westeurope"
  resource_group_name = "test1"
  sku                 = "PerGB2018"
  retention_in_days   = 30
}

resource "azurerm_storage_account" "core" {
  location            = "westeurope"
  resource_group_name = "test1"

  name                      = "corestor${random_string.random.result}"
  account_tier              = "Standard"
  account_replication_type  = "LRS"
  allow_blob_public_access  = "false"
  is_hns_enabled            = true
  enable_https_traffic_only = true
}

resource "azurerm_monitor_diagnostic_setting" "core-diagnostic" {
  name = "readwritecore${random_string.random.result}"
  # See workaround details: https://github.com/terraform-providers/terraform-provider-azurerm/issues/8275#issuecomment-755222989
  target_resource_id         = "${azurerm_storage_account.core.id}/blobServices/default/"
  log_analytics_workspace_id = azurerm_log_analytics_workspace.core.id

  log {
    category = "StorageRead"
    enabled  = true
  }

  log {
    category = "StorageWrite"
    enabled  = true
  }

  metric {
    category = "Transaction"
    enabled  = true
    retention_policy {
      days    = 5
      enabled = true
    }
  }
}