Bootstrapping an embedded ratpack app

gistfile1.groovy

import ratpack.groovy.handling.GroovyChainAction
import ratpack.guice.BindingsSpecAction
import ratpack.guice.Guice
import ratpack.handling.Context
import ratpack.launch.LaunchConfigBuilder
import ratpack.server.BindAddress
import ratpack.server.PublicAddress
import ratpack.server.RatpackServerBuilder


class HostHeaderBasedPublicAddress implements PublicAddress {
  @Override
  URI getAddress(Context context) {
    def bindAddress = context.bindAddress
    def host = context.request.headers.get("host")
    if (host) {
      new URI("http://$host:$bindAddress.port")
    } else {
      new URI("http://$bindAddress.host:$bindAddress.port")
    }
  }
}

def launchConfig = LaunchConfigBuilder.
  noBaseDir().
  build { launchConfig ->
    try {
      def handlers = new GroovyChainAction() {
        protected void execute() throws Exception {
          get { PublicAddress publicAddress ->
            render "public address: ${publicAddress.getAddress(context)}"
          }
        }
      }

      def bindings = new BindingsSpecAction() {
        protected void execute() throws Exception {
          bind(PublicAddress, HostHeaderBasedPublicAddress)
        }
      }

      Guice.handler(launchConfig, bindings, handlers)
    } catch (e) {
      e.printStackTrace()
    }
  }

def server = RatpackServerBuilder.build(launchConfig)

server.start()