Ballerina client for HTTP/2 server push

http2-server-push--client-1.1.0.bal

import ballerina/http;
import ballerina/log;

http:Client clientEP = new("http://localhost:9095", config = { httpVersion: "2.0" });

public function main() {

    // Submit a `GET` request.
    http:Request serviceReq = new;
    http:HttpFuture httpFuture = checkpanic clientEP->submit("GET", "/hello/sayHello", serviceReq);

    // Get the requested resource response.
    http:Response response = checkpanic clientEP->getResponse(httpFuture);
    json responsePayload = checkpanic response.getJsonPayload();
    log:printInfo("Response : " + responsePayload.toString());

    // Check if promises exists.
    boolean hasPromise = clientEP->hasPromise(httpFuture);

    // Get the response for the promises.
    while (hasPromise) {
        http:PushPromise pushPromise = checkpanic clientEP->getNextPromise(httpFuture);
        log:printInfo("Received a promise for " + pushPromise.path);

        // Fetch required promise responses.
        http:Response promisedResponse = checkpanic clientEP->getPromisedResponse(pushPromise);
        json promisedPayload = checkpanic promisedResponse.getJsonPayload();
        log:printInfo("Promised resource : " + promisedPayload.toString());

        // Check if more promises exists.
        hasPromise = clientEP->hasPromise(httpFuture);
    }
}