Bootstrap 3-compatible Rails confirmation dialog

confirm_dialog.js.coffee

$.rails.allowAction = (element) ->
  message = element.data('confirm')
  return true unless message

  proceed = element.data('confirm-proceed') ? 'Proceed'
  cancel = element.data('confirm-cancel') ? 'Cancel'
  title = element.data('confirm-title') ? 'Confirm'
  cancel_button_class = element.data('confirm-cancel-class') ? 'btn-default'
  proceed_button_class = element.data('confirm-proceed-class') ? 'btn-danger'

  $link = element.clone()
    .removeAttr('class')
    .removeAttr('data-confirm')
    .addClass('btn').addClass(proceed_button_class)
    .html(proceed)

  modal_html = """
                <div class="modal fade" id="confirmation_dialog">
                  <div class="modal-dialog">
                    <div class="modal-content">
                      <div class="modal-header">
                        <button type="button" class="close" data-dismiss="modal" aria-hidden="true">
                          <i class="glyphicon glyphicon-remove"></i>
                        </button>
                        <h4>#{title}</h4>
                      </div>
                      <div class="modal-body">
                        <p>#{message}</p>
                      </div>
                      <div class="modal-footer">
                        <button data-dismiss="modal" class="btn #{cancel_button_class}">#{cancel}</button>
                      </div>
                    </div>
                  </div>
                </div>
               """
  $modal_html = $(modal_html)
  $modal_html.find('.modal-footer').append($link)
  $modal_html.modal()
  return false